blob: 39059a3c0429bae159a571bb59191d46ca9d7f5f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
#!/usr/bin/perl
# convert end of line patterns from DOS to UNIX
use strict;
use warnings;
use File::Find;
use File::Temp;
my $buildroot = $ENV{RPM_BUILD_ROOT};
die "No build root defined" unless $buildroot;
die "Invalid build root" unless -d $buildroot;
# normalize build root
$buildroot =~ s|/$||;
my %exclude_files = (
map { $buildroot . $_ => 1 }
split(' ', $ENV{EXCLUDE_FROM_EOL_CONVERSION})
);
find(\&convert, $buildroot);
sub convert {
# reject symlinks
return unless -f $_;
# reject binary files
return unless -T $_;
# reject excluded files
return if $exclude_files{$File::Find::name};
# check if first line has less than 80 characters and ends with \r\n
open(my $in, '<', $_) or die "Unable to open file $_: $!";
my $line = <$in>;
if (length($line) <= 80 && $line =~ s/\r\n$/\n/) {
# process all file
my $out = File::Temp->new(DIR => '.', UNLINK => 0);
print $out $line;
while (($line = <$in>) && defined $line) {
$line =~ s/\r\n$/\n/;
print $out $line;
}
my $tmp = $out->filename;
$out = undef;
# rename file, taking care to keep original permissions
my $perms = (stat $_)[2] & 07777;
rename($tmp, $_) or die "Unable to rename $tmp to $_: $!";
chmod($perms, $_);
}
close($in);
}
|
