index : forums	master
	The forums.mageia.org Website	Maat [maat]

aboutsummaryrefslogtreecommitdiffstats

log msg author committer range

path: root/phpBB/phpbb/message/user_form.php

diff options

context:	12345678910152025303540
space:	includeignore
mode:	unifiedssdiffstat only

author	Tristan Darricau <tristan.darricau@sensiolabs.com>	2015-12-15 20:13:59 +0100
committer	Tristan Darricau <tristan.darricau@sensiolabs.com>	2016-01-09 15:35:17 +0100
commit	761fa9da52e92efafa6839938113ddb55cd85f17 (patch)
tree	17eec1bb1607c8a0f33a72060810dd87118e9e42 /phpBB/phpbb/message/user_form.php
parent	78349ed80f24cb61ad05f997e97d805cc5b0409f (diff)
download	forums-761fa9da52e92efafa6839938113ddb55cd85f17.tar forums-761fa9da52e92efafa6839938113ddb55cd85f17.tar.gz forums-761fa9da52e92efafa6839938113ddb55cd85f17.tar.bz2 forums-761fa9da52e92efafa6839938113ddb55cd85f17.tar.xz forums-761fa9da52e92efafa6839938113ddb55cd85f17.zip

[ticket/14306] Doesn't try to build a "safe" container in the dev env

PHPBB3-14306

Diffstat (limited to 'phpBB/phpbb/message/user_form.php')

0 files changed, 0 insertions, 0 deletions

generated by cgit v1.2.1 (git 2.21.0) at 2025-08-18 03:43:22 +0000

#define _ASM
#define _SETJMP_H
#include <bits/setjmp.h>


#define ENV(base,reg) [%base + (reg * 4)]
#define ST_FLUSH_WINDOWS 3
#define RW_FP [%fp + 0x48]

.text
.global __longjmp
__longjmp:
	/* Store our arguments in global registers so we can still
	   use them while unwinding frames and their register windows.  */

	ld ENV(o0,JB_FP), %g3   /* Cache target FP in register %g3.  */
	mov %o0, %g1            /* ENV in %g1 */
	orcc %o1, %g0, %g2      /* VAL in %g2 */
	be,a 0f                 /* Branch if zero; else skip delay slot.  */
	 mov 1, %g2             /* Delay slot only hit if zero: VAL = 1.  */
0:
	xor %fp, %g3, %o0
	add %fp, 512, %o1
	andncc %o0, 4095, %o0
	bne .Lthread
	 cmp %o1, %g3
	bl .Lthread

	/* Now we will loop, unwinding the register windows up the stack
	   until the restored %fp value matches the target value in %g3.  */

.Lloop:
	cmp %fp, %g3            /* Have we reached the target frame? */
	bl,a .Lloop             /* Loop while current fp is below target.  */
	 restore                /* Unwind register window in delay slot.  */
	be,a .Lfound            /* Better have hit it exactly.  */
	 ld ENV(g1,JB_SP), %o0  /* Delay slot: extract target SP.  */

.Lthread:
	/*
	 * Do a "flush register windows trap".  The trap handler in the
	 * kernel writes all the register windows to their stack slots, and
	 * marks them all as invalid (needing to be sucked up from the
	 * stack when used).  This ensures that all information needed to
	 * unwind to these callers is in memory, not in the register
	 * windows.
	 */
	ta      ST_FLUSH_WINDOWS
	ld      ENV(g1,JB_PC), %o7 /* Set return PC. */
	ld      ENV(g1,JB_SP), %fp /* Set saved SP on restore below. */
	sub     %fp, 64, %sp    /* Allocate a register frame. */
	st      %g3, RW_FP      /* Set saved FP on restore below. */
	retl
	 restore %g2, 0, %o0    /* Restore values from above register frame. */

.Lfound:
	/* We have unwound register windows so %fp matches the target.  */
	mov %o0, %sp            /* OK, install new SP.  */

.Lsp_ok:
	ld ENV(g1,JB_PC), %o0   /* Extract target return PC.  */
	jmp %o0 + 8             /* Return there.  */
	 mov %g2, %o0           /* Delay slot: set return value.  */

.size __longjmp, . - __longjmp