1 files changed, 74 insertions, 0 deletions
diff --git a/lib/Youri/Submit/Action/Install.pm b/lib/Youri/Submit/Action/Install.pm
new file mode 100644
index 0000000..c9a419f
--- /dev/null
+++ b/lib/Youri/Submit/Action/Install.pm
@@ -0,0 +1,74 @@
+# $Id: Install.pm 1689 2007-06-28 22:44:24Z guillomovitch $
+package Youri::Submit::Action::Install;
+
+=head1 NAME
+
+Youri::Submit::Action::Install - Package installation
+
+=head1 DESCRIPTION
+
+This action plugin ensures installation of new package revisions.
+
+=cut
+
+use warnings;
+use strict;
+use Carp;
+use File::Copy;
+use File::Path;
+use File::Basename;
+use base qw/Youri::Submit::Step/;
+
+sub _init {
+    my $self   = shift;
+    my %options = (
+        perms => 644,
+        @_
+    );
+
+    $self->{_perms} = $options{perms};
+
+    return $self;
+}
+
+sub process_packages {
+    my ($self, $packages, $repository, $target, $context) = @_;
+    croak "Not a class method" unless ref $self;
+
+    foreach my $package (@$packages) {
+        my $file = $package->as_file();
+        my $dest = $repository->get_install_dir($package, $target, $context);
+
+        print "installing file $file to $dest\n" if $self->{_verbose};
+
+        unless ($self->{_test}) {
+            # create destination dir if needed
+            if (! -d $dest) {
+                eval {
+                    mkpath($dest, 0, ($self->{_perms} + 111));
+                };
+                if ($@) {
+                    croak "Unable to create directory $dest: $@";
+                }
+            }
+
+            # copy file to new location
+            copy($file, $dest)
+                or croak "Unable to copy file $file to $dest: $!";
+
+            # set permissions
+            chmod oct($self->{_perms}), $dest . '/' . basename($file)
+                or croak "Unable to set perms of file $file to $self->{_perms}: $!";
+        }
+    }
+}
+
+=head1 COPYRIGHT AND LICENSE
+
+Copyright (C) 2002-2006, YOURI project
+
+This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
+
+=cut
+
+1;