#!/usr/bin/perl
# $Id$
# Strip files

use strict;
use warnings;
use File::Find;

################################################################################
# Check if a file is an elf binary, shared library, or static library,
# for use by File::Find. It'll fill the following 3 arrays with anything
# it finds:
my (@shared_libs, @executables, @static_libs);
my $exclude_pattern = join('|',
    map { '(:?' . quotemeta($_) . ')' }
    $ENV{EXCLUDE_FROM_STRIP} ?
        split(' ', $ENV{EXCLUDE_FROM_STRIP}) : (),
    '/usr/lib/debug'
);
$exclude_pattern = qr/$exclude_pattern/;

# TODO: we should write a binding for libfile...
sub expensive_test {
    my ($file) = @_;
    my $type = `file -- $file`;
}

sub testfile() {
    # skip symlinks
    return if -l $_;
    # skip directories
    return if -d $_;
    # skip excluded files
    return if $File::Find::name =~ $exclude_pattern;

    # Does its filename look like a shared library?
    if (m/\.so/) {
        # Ok, do the expensive test.
        if (expensive_test($_) =~ m/ELF.*shared/) {
            push @executables, $File::Find::name;
            return;
        }
    }
    
    # Is it executable? -x isn't good enough, so we need to use stat.
    my (undef, undef, $mode, undef) = stat(_);
    if ($mode & 0111) {
        # Ok, expensive test.
        if (expensive_test($_) =~ m/ELF.*executable/) {
            push @executables, $File::Find::name;
            return;
        }
    }
    
    # Is it a static library, and not a debug library?
    if (m/lib.*\.a/ && ! m/_g\.a/) {
        push @static_libs, $File::Find::name;
        return;
    }
}

################################################################################
my $buildroot = $ENV{RPM_BUILD_ROOT};
die "No build root defined" unless $buildroot;
die "Invalid build root" unless -d $buildroot;
chdir($buildroot) or die "Can't cd to $buildroot: $!";

@shared_libs = @executables = @static_libs = ();
find(\&testfile, $buildroot);

# Note that all calls to strip on shared libs *must* include the
# --strip-unneeded.
system(
    "strip",
    "--remove-section=.comment",
    "--remove-section=.note",
    "--strip-unneeded",
    $_) foreach @shared_libs;

system(
    "strip",
    "--remove-section=.comment",
    "--remove-section=.note",
    $_) foreach @executables;