path: root/mgaapplet-upgrade-helper

#!/usr/bin/perl
################################################################################
# Mageia Online Distribution Upgrade Helper                                    #
#                                                                              #
# Copyright (C) 2008-2010 Mandriva                                             #
#               2010-2015 Mageia                                               #
#                                                                              #
# Thierry Vignaud <thierry.vignaud at gmail dot com>                           #
#                                                                              #
# This program is free software; you can redistribute it and/or modify         #
# it under the terms of the GNU General Public License Version 2 as            #
# published by the Free Software Foundation.                                   #
#                                                                              #
# This program is distributed in the hope that it will be useful,              #
# but WITHOUT ANY WARRANTY; without even the implied warranty of               #
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the                #
# GNU General Public License for more details.                                 #
#                                                                              #
# You should have received a copy of the GNU General Public License            #
# along with this program; if not,  see <http://www.gnu.org/licenses/>.        #
################################################################################

use strict;
use POSIX ":sys_wait_h";
use lib qw(/usr/lib/libDrakX);
use standalone; # for explanations
use common;
BEGIN { require_root_capability() }
use run_program;
use feature 'state';

BEGIN { unshift @::textdomains, 'mgaonline' }

use mygtk3 qw(gtknew); #- do not import gtkadd which conflicts with ugtk3 version
use ugtk3 qw(:all);
use interactive;
use do_pkgs;
use lib qw(/usr/lib/libDrakX/drakfirsttime);
use mgaonline;
use Rpmdrake::open_db;
use lang;
use mgaapplet_gui qw(run_ask_credentials_dialog);

ugtk3::add_icon_path("/usr/share/mgaonline/pixmaps/");
my ($log_file);

my ($new_distro_version, $download_dir);
foreach my $opt (@ARGV) {
    if ($opt =~ /--(rpm-root|urpmi-root)=(.*)/) {
        $::rpmdrake_options{$1}[0] = $2;
    } elsif ($opt =~ /--new_distro_version=(.*)/) {
        $new_distro_version = $1;
    } elsif ($opt =~ /--download-all=(.*)/) {
        $download_dir = $1;
    }
}

die("Usage: mgaapplet-upgrade-helper --new_distro_version=n [--rpm-root-dir] [--urpmi-root=dir] [--download-all=dir]\n") if !$new_distro_version;

$root = Rpmdrake::open_db::fast_open_urpmi_db()->{root};

read_sys_config();
my $product_id = get_product_id();

check_preparation();

if (!$ENV{URPMI_IGNORESIZE}) {
    check_available_free_space('/usr', 800) &&
      check_available_free_space('/var', 800)
	or exit(1);
}

run_program::raw({ detach => 1 }, 'ionice', '-p', $$, '-n7');

upgrade();

my ($refork_gurpmi);

sub check_available_free_space {
    my ($dir, $wanted_MB) = @_;

    my (undef, $free_KB) = MDK::Common::System::df($dir);

    if ($free_KB / 1024 < $wanted_MB) {
	my $msg = ugtk3::escape_text_for_TextView_markup_format(
	    N("Your system does not have enough space left in %s for upgrade (%dMB < %dMB)",
	      $dir,
	      $free_KB / 1024, $wanted_MB));
	ugtk3::ask_warn(N("Error"), $msg);
	0;
    } else {
	1;
    }
}

sub run_gurpmi() {
    # Windows are created before upgrading packages, to guarantee that
    # any possible related GTK upgrade won't affect us...
    my $succeeded_win = create_upgrade_succeeded_window();
    my $failed_win = create_upgrade_failed_window();

    while ($refork_gurpmi) {
        
        my $ok = fork_gurpmi();
        if ($refork_gurpmi && !$ok) {
            $refork_gurpmi--;
        } else {
            undef $refork_gurpmi;
        }

        # update media in case mirrors got updated if needed:
        update_media() if $refork_gurpmi;

        if (!$refork_gurpmi) {
            if (!$ok) {
                $failed_win->main && upgrade();
            } else {
                rm_rf(get_stale_upgrade_filename());
                $succeeded_win->main and !$::testing and any::reboot();
                my $mgaapp_pid = common::is_running('mgaapplet');
                defined($mgaapp_pid) && kill('HUP', $mgaapp_pid);
            }
        }
    }
}

my $width = 500;
my @common = (
    # explicitely wrap (for 2008.1):
    line_wrap => 1,
    # workaround infamous 6 years old gnome bug #101968:
    width => $width - 50,
);

sub create_upgrade_failed_window() {
    local $mygtk3::left_padding = 0;
    my $w = ugtk3->new(N("Error"));
    gtkadd($w->{window},
           gtknew('VBox', children_tight => [
               get_banner(),
               gtknew('Label_Left', text => N("Installation failed"), @common),
               gtknew('Label_Left', text => N("Installation logs can be found in '%s'", $log_file), @common),
               create_okcancel($w, N("Retry"), N("Cancel")),
           ]),
       );
    $w->{ok}->grab_focus;
    return $w;
}

sub create_upgrade_succeeded_window() {
    local $mygtk3::left_padding = 0;
    my $w = ugtk3->new(N("Congratulations"));
    gtkadd($w->{window},
           gtknew('VBox', children_tight => [
               get_banner(),
               gtknew('Label_Left', text => N("Upgrade to Mageia %s release was successful.", $new_distro_version),
                      @common),
               gtknew('Label_Left', text => N("You must restart your system."), @common),
               create_okcancel($w, N("Reboot"), N("Cancel")),
           ]),
       );
    $w->{ok}->grab_focus;
    return $w;
}

sub check_preparation() {
    # Find the matching new_distro_version
    my @distros = get_distro_list();
    if (!@distros) {
        ugtk3::ask_warn(N("Error"), N("Unable to download distro list"));
        die("unable to retrieve distro list\n");
    }

    my $new_distro = find { $_->{version} eq $new_distro_version } @distros;
    if (!$new_distro) {
        ugtk3::ask_warn(N("Error"), N("Distribution version %s was not found in the update list", $new_distro_version));
        die("could not find version '$new_distro_version' in the distro update list\n");
    }

    if ($new_distro->{needs_preparation}) {
        my $statefile = "$root/var/lib/mageia-prepare-upgrade/state";
        my $prepared = -f $statefile && cat_($statefile) =~ /ready/;

        if (!$prepared) {
            ugtk3::ask_yesorno(N("Preparation Required"), N("In order to upgrade, your current installation needs to be prepared.\n\nDo you wish to do this preparation now?")) or exit(0);

            my $in = interactive->vnew;
            my $do_pkgs = do_pkgs::do_pkgs($in);
            $do_pkgs->ensure_is_installed("mageia-prepare-upgrade") or exit(0);

            # Check to see if installation alone is enough to ensure things are in the right state?
            $prepared = -f $statefile && cat_($statefile) =~ /ready/;
            if (!$prepared) {
                my $infofile = "$root/usr/share/doc/mageia-prepare-upgrade/README.prepare";
                my $info = -f $infofile && ugtk3::escape_text_for_TextView_markup_format(join('', cat_($infofile)));
                $info ||= N("Further action is required before you can continue.\n\nPlease see %s for more information.", $new_distro->{url});
                ugtk3::ask_warn(N("Next Steps"), $info);
                exit(0) if !$::testing;
                log::l("I would validate /var/lib/mageia-prepare-upgrade/state == 'ready'");
            }
        }
    }
}

sub upgrade() {
    my $xid = gtkroot()->get_xid;
    
    run_program::raw({ detach => 1 }, 'xdg-screensaver', 'suspend', $xid);
    my $_w = before_leaving { run_program::raw({ detach => 1 }, 'xdg-screensaver', 'resume', $xid) };
   
    my $file = "$ENV{HOME}/.MgaOnline/urpmi.cfg.backup." . int(rand 100000);
    log::explanations("backuping urpmi configuration in $file");
    cp_af("$root/etc/urpmi/urpmi.cfg", $file);

    my $urpm = Rpmdrake::open_db::fast_open_urpmi_db();

    my $urpmi_lock = eval {
        local $urpm->{fatal} = sub { die @_ };
        urpm::lock::urpmi_db($urpm, 'exclusive');
    };

    if (my $err = $@) {
        log::explanations(sprintf("locking urpmi database failed: %s"), $err);
        ugtk3::ask_warn(N("Error"),
                        N("Installation failed"),
                        '',
                        formatAlaTeX(N("Packages database is locked. Please close other applications
working with packages database (do you have another media
manager on another desktop, or are you currently installing
packages as well?)."))
                    );
        exit(1);
    }

    my ($nonfree, $tainted);

    log::explanations("Checking for enabled Nonfree/Tainted");
    foreach my $media (@{$urpm->{media}}) {
        log::explanations("Checking $media->{name}");
        if (!defined($media->{ignore})) {
            log::explanations("Media $media->{name} is not ignored");
            if ($media->{name} =~ /^Nonfree/) {
                $nonfree = 1;
                log::explanations("Nonfree found to be enabled");
            }
            if ($media->{name} =~ /^Tainted/) {
                $tainted = 1;
                log::explanations("Tainted found to be enabled");
            }
        }
    }

    undef $urpmi_lock;

    touch(get_stale_upgrade_filename());

    log::explanations("removing all existing urpmi media for upgrade");
    run_program::run('urpmi.removemedia', if_($root, '--urpmi-root', $root), '-a');

    #- clear the mirror cache before upgrading:
    eval { rm_rf("$::prefix/var/cache/urpmi/mirrors.cache") };

    $urpm = Rpmdrake::open_db::fast_open_urpmi_db();
    if ($urpm->{global_config}{downloader}) {
        log::explanations("disabling custom downloader in order to use aria2");
        delete $urpm->{global_config}{downloader};
        urpm::media::write_config($urpm);
    }

    log::explanations("adding urpmi media for new distribution");

    $ENV{URPMI_ADDMEDIA_REASON} = join(',', 'reason=upgrade', 'upgrade_by=mgaapplet', "upgrade_from=$product_id->{version}");
    # the following modifies $MIRRORLIST expansion in urpm/mirrors.pm,
    # it must be set for gurpmi.addmedia, but also for gurpmi
    $ENV{URPMI_ADDMEDIA_PRODUCT_VERSION} = $new_distro_version;

    system('gurpmi.addmedia', '--silent-success', if_($root, "--urpmi-root=$root"), '--distrib', '--mirrorlist', '$MIRRORLIST') and do {
        log::explanations("adding media for new distribution failed");
        rm_rf(get_stale_upgrade_filename());
        log::explanations("restoringing urpmi configuration from $file");
        cp_af($file, "$root/etc/urpmi/urpmi.cfg");
        update_media();
        ugtk3::ask_warn(N("Error"),
                        N("Installation failed"),
                        N("Failure when adding medium"),
                    );
        exit(2);
    };

    if ($nonfree || $tainted) {
        if ($nonfree) {
            log::explanations("enabling nonfree as it was there before upgrade");
            enable_media("Nonfree");
        }

        if ($tainted) {
            log::explanations("enabling tainted as it was there before upgrade");
            enable_media("Tainted");
        }

        # Media was added, update it and move along...
        update_media();
    }

    log::explanations("upgrading urpmi and rpmdrake");
    log::explanations("upgrading the whole system");

    # rerun gurpmi in case there was an issue (with eg: big transactions:
    $refork_gurpmi = 4;
    {
        # force PATH:
        local $ENV{TMPDIR} = undef;
	my $log_template = 
	    "gurpmi_upgrade_to_${new_distro_version}_XXXXXXXX";
        $log_file = chomp_(`mktemp -u --tmpdir=$ENV{HOME}/.MgaOnline/ --suffix=.log $log_template`);
        log::explanations("logging gurpmi message in '$log_file'");
    }

    # we cannot use installUpdates() as MandrivaUpdate needs the media
    # flaged as update (or else, we need to add a new option to MandrivaUpdate):
    run_gurpmi();
}

sub fork_gurpmi {
    run_program::raw({ timeout => 'never' },
		     'gurpmi', '>>', $log_file, '2>>', $log_file, '--auto', '--auto-select', '--replacefiles', '--clean',
                      if_($root, "--urpmi-root=$root"),
                      if_($download_dir, "--download-all=$download_dir"));
}

sub update_media() {
    run_program::run('urpmi.update', if_($root, '--urpmi-root', $root), '-a');
}

sub enable_media {
    my ($repos) = @_;
    run_program::run('urpmi.update', if_($root, '--urpmi-root', $root), '--no-ignore', "$repos Release", "$repos Updates");
}