package pkgs; # $Id$
use strict;
use URPM;
use URPM::Resolve;
use URPM::Signature;
use common;
use install_any;
use run_program;
use detect_devices;
use log;
use fs;
use fs::loopback;
use c;
our %preferred = map { $_ => undef } qw(lilo nail perl-base openjade ctags glibc glibc-devel curl sane-backends postfix gcc gcc-cpp gcc-c++ proftpd vim-minimal db1 libxpm4 zlib1 libncurses5 harddrake cups);
#- lower bound on the left ( aka 90 means [90-100[ )
our %compssListDesc = (
5 => N_("must have"),
4 => N_("important"),
3 => N_("very nice"),
2 => N_("nice"),
1 => N_("maybe"),
);
#- constant for small transaction.
our $limitMinTrans = 13;
#- package to ignore, typically in Application CD. OBSOLETED ?
my %ignoreBadPkg = (
'civctp-demo' => 1,
'eus-demo' => 1,
'myth2-demo' => 1,
'heretic2-demo' => 1,
'heroes3-demo' => 1,
'rt2-demo' => 1,
);
sub packageMedium {
my ($packages, $p) = @_; $p or die "invalid package from\n" . backtrace();
foreach (values %{$packages->{mediums}}) {
defined $_->{start} && defined $_->{end} or next;
$p->id >= $_->{start} && $p->id <= $_->{end} and return $_;
}
return {};
}
sub cleanHeaders() {
rm_rf("$::prefix/tmp/headers") if -e "$::prefix/tmp/headers";
}
#- get all headers from an hdlist file.
sub extractHeaders {
my ($pkgs, $media) = @_;
my %medium2pkgs;
cleanHeaders();
foreach (@$pkgs) {
foreach my $medium (values %$media) {
$_->id >= $medium->{start} && $_->id <= $medium->{end} or next;
push @{$medium2pkgs{$medium->{medium}} ||= []}, $_;
}
}
foreach (keys %medium2pkgs) {
my $medium = $media->{$_};
eval {
require packdrake;
my $packer = new packdrake("/tmp/$medium->{hdlist}", quiet => 1);
$packer->extract_archive("$::prefix/tmp/headers", map { $_->header_filename } @{$medium2pkgs{$_}});
};
}
foreach (@$pkgs) {
my $f = "$::prefix/tmp/headers/" . $_->header_filename;
$_->update_header($f) or log::l("unable to open header file $f"), next;
log::l("read header file $f");
}
}
#- TODO BEFORE TODO
#- size and correction size functions for packages.
my $B = 1.20873;
my $C = 4.98663; #- does not take hdlist's into account as getAvailableSpace will do it.
sub correctSize { $B * $_[0] + $C }
sub invCorrectSize { ($_[0] - $C) / $B }
sub selectedSize {
my ($packages) = @_;
my $size = 0;
my %skip;
#- take care of packages selected...
foreach (@{$packages->{depslist}}) {
if ($_->flag_selected) {
$size += $_->size;
#- if a package is obsoleted with the same name it should
#- have been selected, so a selected new package obsoletes
#- all the old package.
exists $skip{$_->name} and next; $skip{$_->name} = undef;
$size -= $packages->{sizes}{$_->name};
}
}
#- but remove size of package being obsoleted or removed.
foreach (keys %{$packages->{state}{rejected}}) {
my ($name) = /(.*)-[^\-]*-[^\-]*$/ or next;
exists $skip{$name} and next; $skip{$name} = undef;
$size -= $packages->{sizes}{$name};
}
$size;
}
sub size2time {
my ($x, $max) = @_;
my $A = 7e-07;
my $limit = min($max * 3 / 4, 9e8);
if ($x < $limit) {
$A * $x;
} else {
$x -= $limit;
my $B = 6e-16;
my $C = 15e-07;
$B * $x ** 2 + $C * $x + $A * $limit;
}
}
sub packagesProviding {
my ($packages, $name) = @_;
map { $packages->{depslist}[$_] } keys %{$packages->{provides}{$name} || {}};
}
#- searching and grouping methods.
#- package is a reference to list that contains
#- a hash to search by name and
#- a list to search by id.
sub packageByName {
my ($packages, $name) = @_;
#- search package with given name and compatible with current architecture.
#- take the best one found (most up-to-date).
my @packages;
foreach my $pkg (packagesProviding($packages, $name)) {
$pkg->is_arch_compat or next;
$pkg->name eq $name or next;
push @packages, $pkg;
}
my $best;
foreach (@packages) {
if ($best && $best != $_) {
$_->compare_pkg($best) > 0 and $best = $_;
} else {
$best = $_;
}
}
$best or log::l("unknown package `$name'");
$best;
}
sub analyse_kernel_name {
my $kernels = join('|', map { "-$_" }
'(p3|i586|i686)-(up|smp)-(1GB|4GB|64GB)',
qw(enterprise secure smp multimedia multimedia-smp xbox),
);
my @l = $_[0] =~ /kernel[^\-]*($kernels)?(-([^\-]+))?$/ or return;
$l[0], $l[-1];
}
sub packages2kernels {
my ($packages) = @_;
sort {
$a->{ext} cmp $b->{ext} || URPM::rpmvercmp($b->{version}, $a->{version});
} map {
if (my ($ext, $version) = analyse_kernel_name($_->name)) {
{ pkg => $_, ext => $ext, version => $version };
} else {
log::l("ERROR: unknown package " . $_->name . " providing kernel");
();
}
} packagesProviding($packages, 'kernel');
}
sub bestKernelPackage {
my ($packages) = @_;
my @kernels = packages2kernels($packages) or internal_error('no kernel available');
my ($version_BOOT) = c::kernel_version() =~ /^(\d+\.\d+)/;
if (my @l = grep { $_->{version} =~ /\Q$version_BOOT/ } @kernels) {
#- favour versions corresponding to current BOOT version
@kernels = @l;
}
my @preferred_exts =
$::build_globetrotter ? '' :
detect_devices::is_xbox() ? '-xbox' :
detect_devices::is_i586() ? '-i586-up-1GB' :
!detect_devices::has_cpu_flag('pae') ? ('-i686-up-4GB', '-i586-up-1GB') :
detect_devices::hasSMP() ? '-smp' :
'';
foreach my $prefered_ext (@preferred_exts, '') {
if (my @l = grep { $_->{ext} eq $prefered_ext } @kernels) {
@kernels = @l;
}
}
log::l("bestKernelPackage (" . join(':', @preferred_exts) . "): " . join(' ', map { $_->{pkg}->name } @kernels) . (@kernels > 1 ? ' (choosing the first)' : ''));
$preferred{'kernel-source-' . $kernels[0]{version}} = undef;
$kernels[0]{pkg};
}
sub packagesOfMedium {
my ($packages, $medium) = @_;
defined $medium->{start} && defined $medium->{end} ? @{$packages->{depslist}}[$medium->{start} .. $medium->{end}] : ();
}
sub packagesToInstall {
my ($packages) = @_;
my @packages;
foreach (values %{$packages->{mediums}}) {
$_->{selected} or next;
log::l("examining packagesToInstall of medium $_->{descr}");
push @packages, grep { $_->flag_selected } packagesOfMedium($packages, $_);
}
log::l("found " . scalar(@packages) . " packages to install");
@packages;
}
sub allMediums {
my ($packages) = @_;
sort {
#- put supplementary media at the end
my @x = ($a, $b);
foreach (@x) { install_medium::by_id($_, $packages)->is_suppl and $_ += 100 }
$x[0] <=> $x[1];
} keys %{$packages->{mediums}};
}
sub packageRequest {
my ($packages, $pkg) = @_;
#- check if the same or better version is installed,
#- do not select in such case.
$pkg && ($pkg->flag_upgrade || !$pkg->flag_installed) or return;
#- check for medium selection, if the medium has not been
#- selected, the package cannot be selected.
foreach (values %{$packages->{mediums}}) {
!$_->{selected} && $pkg->id >= $_->{start} && $pkg->id <= $_->{end} and return;
}
return { $pkg->id => 1 };
}
sub packageCallbackChoices {
my ($urpm, $_db, $state, $choices) = @_;
if (my $prefer = find { $_->arch ne 'src' && exists $preferred{$_->name} } @$choices) {
log::l("packageCallbackChoices: prefered choice " . $prefer->name . " from ", join(",", map { $_->name } @$choices));
$prefer;
} else {
my @l = grep {
#- or even if a package requires a specific locales which
#- is already selected.
find {
/locales-/ && do {
my $p = packageByName($urpm, $_);
$p && $p->flag_available;
};
} $_->requires_nosense;
} @$choices;
if (!@l) {
@l = $choices->[0];
log::l("packageCallbackChoices: default choice from ", join(",", map { $_->name } @$choices), " in ", join(",", map { $urpm->{depslist}[$_]->name } keys %{$state->{selected}}));
}
#-log::l("packageCallbackChoices: chosen " . join(" ", map { $_->name } @l));
@l;
}
}
sub select_by_package_names {
my ($packages, $names, $b_base, $o_otherOnly) = @_;
foreach (@$names) {
my $p = packageByName($packages, $_) or next;
selectPackage($packages, $p, $b_base, $o_otherOnly);
}
}
#- selection, unselection of package.
sub selectPackage {
my ($packages, $pkg, $b_base, $o_otherOnly) = @_;
#- select package and dependancies, o_otherOnly may be a reference
#- to a hash to indicate package that will strictly be selected
#- when value is true, may be selected when value is false (this
#- is only used for unselection, not selection)
my $state = $packages->{state} ||= {};
$packages->{rpmdb} ||= rpmDbOpen();
my @l = $packages->resolve_requested($packages->{rpmdb}, $state, packageRequest($packages, $pkg) || {},
callback_choices => \&packageCallbackChoices);
if ($b_base || $o_otherOnly) {
foreach (@l) {
$b_base and $_->set_flag_base;
$o_otherOnly and $o_otherOnly->{$_->id} = $_->flag_requested;
}
$o_otherOnly and $packages->disable_selected($packages->{rpmdb}, $state, @l);
}
1;
}
sub unselectPackage($$;$) {
my ($packages, $pkg, $o_otherOnly) = @_;
#- base packages are not unselectable,
#- and already unselected package are no more unselectable.
$pkg->flag_base and return;
$pkg->flag_selected or return;
my $state = $packages->{state} ||= {};
log::l("removing selection on package " . $pkg->fullname);
my @l = $packages->disable_selected($packages->{rpmdb}, $state, $pkg);
log::l(" removed selection on package " . $pkg->fullname . "gives " . join(',', map { scalar $_->fullname } @l));
if ($o_otherOnly) {
foreach (@l) {
$o_otherOnly->{$_->id} = undef;
}
log::l(" reselecting removed selection...");
$packages->resolve_requested($packages->{rpmdb}, $state, $o_otherOnly, callback_choices => \&packageCallbackChoices);
log::l(" done");
}
1;
}
sub unselectAllPackages($) {
my ($packages) = @_;
my %keep_selected;
log::l("unselecting all packages...");
foreach (@{$packages->{depslist}}) {
if ($_->flag_base || $_->flag_installed && $_->flag_selected) {
#- keep track of packages that should be kept selected.
$keep_selected{$_->id} = $_;
} else {
#- deselect all packages except base or packages that need to be upgraded.
$_->set_flag_required(0);
$_->set_flag_requested(0);
}
}
#- clean state, in order to start with a brand new set...
$packages->{state} = {};
$packages->resolve_requested($packages->{rpmdb}, $packages->{state}, \%keep_selected,
callback_choices => \&packageCallbackChoices);
}
sub urpmidir() {
my $v = "$::prefix/var/lib/urpmi";
-l $v && !-e _ and unlink $v and mkdir $v, 0755; #- dangling symlink
-w $v ? $v : '/tmp';
}
sub psUpdateHdlistsDeps {
my ($packages) = @_;
my $need_copy = 0;
my $urpmidir = urpmidir();
#- check if current configuration is still up-to-date and do not need to be updated.
foreach (values %{$packages->{mediums}}) {
next if ref $_ ne 'install_medium'; #- skip empty hash artifact
$_->selected || $_->ignored or next;
my $hdlistf = "$urpmidir/hdlist.$_->{fakemedium}.cz" . ($_->{hdlist} =~ /\.cz2/ && "2");
my $synthesisf = "$urpmidir/synthesis.hdlist.$_->{fakemedium}.cz" . ($_->{hdlist} =~ /\.cz2/ && "2");
if (-s $hdlistf != $_->{hdlist_size}) {
install_any::getAndSaveFile("media/media_info/$_->{hdlist}", $hdlistf) or die "no $_->{hdlist} found";
symlinkf $hdlistf, "/tmp/$_->{hdlist}";
++$need_copy;
chown 0, 0, $hdlistf;
}
if (-s $synthesisf != $_->{synthesis_hdlist_size}) {
install_any::getAndSaveFile("media/media_info/synthesis.$_->{hdlist}", $synthesisf);
if (-s $synthesisf > 0) { chown 0, 0, $synthesisf } else { unlink $synthesisf }
}
}
if ($need_copy) {
#- this is necessary for urpmi.
install_any::getAndSaveFile("media/media_info/$_", "$urpmidir/$_") && chown 0, 0, "$urpmidir/$_" foreach qw(rpmsrate);
}
}
sub psUsingHdlists {
my ($o, $method, $o_hdlistsprefix, $o_packages, $o_initialmedium, $o_callback) = @_;
my $is_ftp = $o_hdlistsprefix =~ /^ftp:/;
my $listf = install_any::getFile($o_hdlistsprefix && !$is_ftp ? "$o_hdlistsprefix/media/media_info/hdlists" : 'media/media_info/hdlists')
or die "no hdlists found";
my ($suppl_CDs, $deselectionAllowed) = ($o->{supplmedia} || 0, $o->{askmedia} || 0);
if (!$o_packages) {
$o_packages = new URPM;
#- add additional fields used by DrakX.
@$o_packages{qw(count mediums)} = (0, {});
}
#- parse hdlists file.
my $medium_name = $o_initialmedium || 1;
my (@hdlists, %mediumsize);
foreach (<$listf>) {
chomp;
s/\s*#.*$//;
/^\s*$/ and next;
#- we'll ask afterwards for supplementary CDs, if the hdlists file contains
#- a line that begins with "suppl"
if (/^suppl/) { $suppl_CDs = 1; next }
#- if the hdlists contains a line "askmedia", deletion of media found
#- in this hdlist is allowed
if (/^askmedia/) { $deselectionAllowed = 1; next }
my $cdsuppl = index($medium_name, 's') >= 0;
my ($noauto, $hdlist, $rpmsdir, $descr, $size) = m/^\s*(noauto:)?(hdlist\S*\.cz2?)\s+(\S+)\s*([^(]*)(\(.+\))?$/
or die qq(invalid hdlist description "$_" in hdlists file);
$descr =~ s/\s+$//;
push @hdlists, [ $hdlist, $medium_name, $rpmsdir, $descr, !$noauto,
#- hdlist path, suppl CDs are mounted on /mnt/cdrom :
$o_hdlistsprefix ? ($is_ftp ? "media/media_info/$hdlist" : "$o_hdlistsprefix/media/media_info/$hdlist") : undef,
];
if ($size) {
($mediumsize{$hdlist}) = $size =~ /(\d+)/; #- XXX assume Mo
} else {
$mediumsize{$hdlist} = 0;
}
$cdsuppl ? ($medium_name = ($medium_name + 1) . 's') : ++$medium_name;
}
my $copy_rpms_on_disk = 0;
if ($deselectionAllowed && !defined $o_initialmedium) {
(my $finalhdlists, $copy_rpms_on_disk) = $o->deselectFoundMedia(\@hdlists, \%mediumsize);
@hdlists = @$finalhdlists;
}
foreach my $h (@hdlists) {
my $medium = psUsingHdlist($method, $o_packages, @$h);
$o_callback and $o_callback->($medium, $o_hdlistsprefix, $method);
}
log::l("psUsingHdlists read " . int(@{$o_packages->{depslist}}) .
" headers on " . int(keys %{$o_packages->{mediums}}) . " hdlists");
return $o_packages, $suppl_CDs, $copy_rpms_on_disk;
}
sub psUsingHdlist {
my ($method, $packages, $hdlist, $medium_name, $rpmsdir, $descr, $selected, $o_fhdlist, $o_pubkey, $o_nocopy) = @_;
my $fakemedium = "$descr ($method$medium_name)";
my $urpmidir = urpmidir();
log::l("trying to read $hdlist for medium $medium_name");
my $m = install_medium->new(
hdlist => $hdlist,
method => $method,
medium => $medium_name,
rpmsdir => $rpmsdir, #- where is RPMS directory.
descr => $descr,
fakemedium => $fakemedium,
selected => $selected, #- default value is only CD1, it is really the minimal.
ignored => !$selected, #- keep track of ignored medium by DrakX.
pubkey => [], #- all pubkey blocks here
);
#- copy hdlist file directly to urpmi directory, this will be used
#- for getting header of package during installation or after by urpmi.
my $newf = "$urpmidir/hdlist.$fakemedium.cz" . ($hdlist =~ /\.cz2/ && "2");
unless ($o_nocopy) {
my $w_wait;
$w_wait = $::o->wait_message(N("Please wait"), N("Downloading file %s...", $hdlist)) if $method =~ /^(?:ftp|http|nfs)$/;
-e $newf and do { unlink $newf or die "cannot remove $newf: $!" };
install_any::getAndSaveFile($o_fhdlist || "media/media_info/$hdlist", $newf) or do { unlink $newf; die "no $hdlist found" };
$m->{hdlist_size} = -s $newf; #- keep track of size for post-check.
symlinkf $newf, "/tmp/$hdlist";
undef $w_wait;
}
my $newsf = "$urpmidir/synthesis.hdlist.$fakemedium.cz" . ($hdlist =~ /\.cz2/ && "2");
#- if $o_fhdlist is a filehandle, it's preferable not to try to find the associated synthesis.
if (!$o_nocopy && !ref $o_fhdlist) {
#- copy existing synthesis file too.
my $synth;
if ($o_fhdlist) {
$synth = $o_fhdlist;
$synth =~ s/hdlist/synthesis.hdlist/ or $synth = undef;
}
$synth ||= "media/media_info/synthesis.$hdlist";
install_any::getAndSaveFile($synth, $newsf);
$m->{synthesis_hdlist_size} = -s $newsf; #- keep track of size for post-check.
-s $newsf > 0 or unlink $newsf;
}
chown 0, 0, $newf, $newsf;
#- get all keys corresponding in the right pubkey file,
#- they will be added in rpmdb later if not found.
if (!$o_fhdlist || $o_pubkey) {
$m->{pubkey} = $o_pubkey;
unless ($m->{pubkey}) {
my $pubkey = install_any::getFile("media/media_info/pubkey" . ($hdlist =~ /hdlist(\S*)\.cz2?/ && $1));
$m->{pubkey} = [ $packages->parse_armored_file($pubkey) ];
}
}
#- integrate medium in media list, only here to avoid download error (update) to be propagated.
$packages->{mediums}{$medium_name} = $m;
#- parse synthesis (if available) of directly hdlist (with packing).
if ($m->ignored) {
log::l("ignoring packages in $hdlist");
} else {
my $nb_suppl_pkg_skipped = 0;
my $callback = sub {
my (undef, $p) = @_;
our %uniq_pkg_seen;
if ($uniq_pkg_seen{$p->fullname}++) {
log::l("skipping " . scalar $p->fullname);
++$nb_suppl_pkg_skipped;
return 0;
} else {
return 1;
}
};
if (-s $newsf) {
($m->{start}, $m->{end}) = $packages->parse_synthesis($newsf, callback => $callback);
} elsif (-s $newf) {
($m->{start}, $m->{end}) = $packages->parse_hdlist($newf, callback => $callback);
} else {
delete $packages->{mediums}{$medium_name};
unlink $newf;
$o_fhdlist or unlink $newsf;
die "fatal: no hdlist nor synthesis to read for $fakemedium";
}
$m->{start} > $m->{end} and do { delete $packages->{mediums}{$medium_name};
unlink $newf;
$o_fhdlist or unlink $newsf;
die "fatal: nothing read in hdlist or synthesis for $fakemedium" };
log::l("read " . ($m->{end} - $m->{start} + 1) . " packages in $hdlist, $nb_suppl_pkg_skipped skipped");
}
$m;
}
sub read_rpmsrate_raw {
my ($f) = @_;
my $line_nb = 0;
my $fatal_error;
my (%flags, %rates, @need_to_copy);
my (@l);
local $_;
while (<$f>) {
$line_nb++;
/\t/ and die "tabulations not allowed at line $line_nb\n";
s/#.*//; # comments
my ($indent, $data) = /(\s*)(.*)/;
next if !$data; # skip empty lines
@l = grep { $_->[0] < length $indent } @l;
my @m = @l ? @{$l[-1][1]} : ();
my ($t, $flag, @l2);
while ($data =~
/^((
[1-5]
|
(?: (?: !\s*)? [0-9A-Z_]+(?:".*?")?)
(?: \s*\|\|\s* (?: !\s*)? [0-9A-Z_]+(?:".*?")?)*
)
(?:\s+|$)
)(.*)/x) { #@")) {
($t, $flag, $data) = ($1,$2,$3);
while ($flag =~ s,^\s*(("[^"]*"|[^"\s]*)*)\s+,$1,) {}
push @m, $flag;
push @l2, [ length $indent, [ @m ] ];
$indent .= $t;
}
if ($data) {
# has packages on same line
my ($rates, $flags) = partition { /^\d$/ } @m;
my ($rate) = @$rates or die sprintf qq(missing rate for "%s" at line %d (flags are %s)\n), $data, $line_nb, join('&&', @m);
foreach my $name (split ' ', $data) {
if (member('INSTALL', @$flags)) {
push @need_to_copy, $name if !member('NOCOPY', @$flags);
next; #- do not need to put INSTALL flag for a package.
}
if (member('PRINTER', @$flags)) {
push @need_to_copy, $name;
}
my @new_flags = @$flags;
if (my $previous = $flags{$name}) {
my @common = intersection($flags, $previous);
my @diff1 = difference2($flags, \@common);
my @diff2 = difference2($previous, \@common);
if (!@diff1 || !@diff2) {
@new_flags = @common;
} elsif (@diff1 == 1 && @diff2 == 1) {
@new_flags = (@common, join('||', $diff1[0], $diff2[0]));
} else {
log::l("can not handle complicate flags for packages appearing twice ($name)");
$fatal_error++;
}
log::l("package $name appearing twice with different rates ($rate != " . $rates{$name} . ")") if $rate != $rates{$name};
}
$rates{$name} = $rate;
$flags{$name} = \@new_flags;
}
push @l, @l2;
} else {
push @l, [ $l2[0][0], $l2[-1][1] ];
}
}
$fatal_error and die "$fatal_error fatal errors in rpmsrate";
\%rates, \%flags, \@need_to_copy;
}
sub read_rpmsrate {
my ($packages, $rpmsrate_flags_chosen, $f) = @_;
my ($rates, $flags, $need_to_copy) = read_rpmsrate_raw($f);
foreach (keys %$flags) {
my $p = packageByName($packages, $_) or next;
my @flags = (@{$flags->{$_}}, map { if_(/locales-(.*)/, qq(LOCALES"$1")) } $p->requires_nosense);
@flags = map {
my ($user_flags, $known_flags) = partition { /^!?CAT_/ } split('\|\|', $_);
my $ok = find {
my $inv = s/^!//;
$inv xor do {
if (my ($p) = /^HW"(.*)"/) {
detect_devices::matching_desc__regexp($p);
} elsif (($p) = /^HW_CAT"(.*)"/) {
modules::probe_category($p);
} elsif (($p) = /^DRIVER"(.*)"/) {
detect_devices::matching_driver__regexp($p);
} elsif (($p) = /^TYPE"(.*)"/) {
detect_devices::matching_type($p);
} else {
$rpmsrate_flags_chosen->{$_};
}
};
} @$known_flags;
$ok ? 'TRUE' : @$user_flags ? join('||', @$user_flags) : 'FALSE';
} @flags;
$p->set_rate($rates->{$_});
$p->set_rflags(member('FALSE', @flags) ? 'FALSE' : @flags);
}
push @{$packages->{needToCopy} ||= []}, @$need_to_copy;
}
sub readCompssUsers {
my ($file) = @_;
my $f = -e $file ? install_any::getLocalFile($file) : install_any::getFile($file)
or do { log::l("can not find $file: $!"); return undef, undef };
my ($compssUsers, $gtk_display_compssUsers) = eval join('', <$f>);
if ($@) {
log::l("ERROR: bad $file: $@");
} else {
log::l("compssUsers.pl got: ", join(', ', map { qq("$_->{path}|$_->{label}") } @$compssUsers));
}
($compssUsers, $gtk_display_compssUsers);
}
sub saveCompssUsers {
my ($packages, $compssUsers) = @_;
my $flat;
foreach (@$compssUsers) {
my %fl = map { ("CAT_$_" => 1) } @{$_->{flags}};
$flat .= "$_->{label} [icon=xxx] [path=$_->{path}]\n";
foreach my $p (@{$packages->{depslist}}) {
my @flags = $p->rflags;
if ($p->rate && any { any { !/^!/ && $fl{$_} } split('\|\|') } @flags) {
$flat .= sprintf "\t%d %s\n", $p->rate, $p->name;
}
}
}
my $urpmidir = urpmidir();
output "$urpmidir/compssUsers.flat", $flat;
}
sub setSelectedFromCompssList {
my ($packages, $rpmsrate_flags_chosen, $min_level, $max_size) = @_;
$rpmsrate_flags_chosen->{TRUE} = 1; #- ensure TRUE is set
my $nb = selectedSize($packages);
foreach my $p (sort { $b->rate <=> $a->rate } @{$packages->{depslist}}) {
my @flags = $p->rflags;
next if
!$p->rate || $p->rate < $min_level ||
any { !any { /^!(.*)/ ? !$rpmsrate_flags_chosen->{$1} : $rpmsrate_flags_chosen->{$_} } split('\|\|') } @flags;
#- determine the packages that will be selected when
#- selecting $p. the packages are not selected.
my $state = $packages->{state} ||= {};
my @l = $packages->resolve_requested($packages->{rpmdb}, $state, packageRequest($packages, $p) || {},
callback_choices => \&packageCallbackChoices);
#- this enable an incremental total size.
my $old_nb = $nb;
foreach (@l) {
$nb += $_->size;
}
if ($max_size && $nb > $max_size) {
$nb = $old_nb;
$min_level = $p->rate;
$packages->disable_selected($packages->{rpmdb}, $state, @l);
last;
}
}
my @flags = map_each { if_($::b, $::a) } %$rpmsrate_flags_chosen;
log::l("setSelectedFromCompssList: reached size ", formatXiB($nb), ", up to indice $min_level (less than ", formatXiB($max_size), ") for flags ", join(' ', sort @flags));
log::l("setSelectedFromCompssList: ", join(" ", sort map { $_->name } grep { $_->flag_selected } @{$packages->{depslist}}));
$min_level;
}
#- useful to know the size it would take for a given min_level/max_size
#- just save the selected packages, call setSelectedFromCompssList, and restore the selected packages
sub saveSelected {
my ($packages) = @_;
my $state = delete $packages->{state};
my @l = @{$packages->{depslist}};
my @flags = map { ($_->flag_requested && 1) + ($_->flag_required && 2) + ($_->flag_upgrade && 4) } @l;
[ $packages, $state, \@l, \@flags ];
}
sub restoreSelected {
my ($packages, $state, $l, $flags) = @{$_[0]};
$packages->{state} = $state;
mapn { my ($pkg, $flag) = @_;
$pkg->set_flag_requested($flag & 1);
$pkg->set_flag_required($flag & 2);
$pkg->set_flag_upgrade($flag & 4);
} $l, $flags;
}
sub computeGroupSize {
my ($packages, $min_level) = @_;
sub inside {
my ($l1, $l2) = @_;
my $i = 0;
return if @$l1 > @$l2;
foreach (@$l1) {
my $c;
while ($c = $l2->[$i++] cmp $_) {
return if $c == 1 || $i > @$l2;
}
}
1;
}
sub or_ify {
my ($first, @other) = @_;
my @l = split('\|\|', $first);
foreach (@other) {
@l = map {
my $n = $_;
map { "$_&&$n" } @l;
} split('\|\|');
}
@l;
}
my %or_ify_cache;
my $or_ify_cached = sub {
$or_ify_cache{$_[0]} ||= join("\t", or_ify(split("\t", $_[0])));
};
sub or_clean {
my ($flags) = @_;
my @l = split("\t", $flags);
@l = map { [ sort split('&&') ] } @l;
my @r;
B: while (@l) {
my $e = shift @l;
foreach (@r, @l) {
inside($_, $e) and next B;
}
push @r, $e;
}
join("\t", map { join('&&', @$_) } @r);
}
my (%group, %memo, $slowpart_counter);
log::l("pkgs::computeGroupSize");
my $time = time();
my %pkgs_with_same_rflags;
foreach (@{$packages->{depslist}}) {
next if !$_->rate || $_->rate < $min_level || $_->flag_available;
my $flags = join("\t", $_->rflags);
next if $flags eq 'FALSE';
push @{$pkgs_with_same_rflags{$flags}}, $_;
}
foreach my $raw_flags (keys %pkgs_with_same_rflags) {
my $flags = $or_ify_cached->($raw_flags);
my @pkgs = @{$pkgs_with_same_rflags{$raw_flags}};
#- determine the packages that will be selected when selecting $p.
#- make a fast selection (but potentially erroneous).
#- installed and upgrade flags must have been computed (see compute_installed_flags).
my %newSelection;
my @l2 = map { $_->id } @pkgs;
my $id;
while (defined($id = shift @l2)) {
exists $newSelection{$id} and next;
$newSelection{$id} = undef;
my $pkg = $packages->{depslist}[$id];
foreach ($pkg->requires_nosense) {
my @choices = keys %{$packages->{provides}{$_} || {}};
if (@choices <= 1) {
push @l2, @choices;
} elsif (! find { exists $newSelection{$_} } @choices) {
my ($candidate_id, $prefer_id);
foreach (@choices) {
++$slowpart_counter;
my $ppkg = $packages->{depslist}[$_] or next;
$ppkg->flag_available and $prefer_id = $candidate_id = undef, last;
exists $preferred{$ppkg->name} and $prefer_id = $_;
$ppkg->name =~ /kernel-\d/ and $prefer_id ||= $_;
foreach my $l ($ppkg->requires_nosense) {
/locales-/ or next;
my $pppkg = packageByName($packages, $l) or next;
$pppkg->flag_available and $prefer_id ||= $_;
}
$candidate_id = $_;
}
if (defined $prefer_id || defined $candidate_id) {
push @l2, defined $prefer_id ? $prefer_id : $candidate_id;
}
}
}
}
foreach (keys %newSelection) {
my $p = $packages->{depslist}[$_] or next;
next if $p->flag_selected; #- always installed (accounted in system_size)
my $s = $group{$p->name} || $or_ify_cached->(join("\t", $p->rflags));
my $m = "$flags\t$s";
$group{$p->name} = ($memo{$m} ||= or_clean($m));
}
}
my (%sizes, %pkgs);
while (my ($k, $v) = each %group) {
my $pkg = packageByName($packages, $k) or next;
push @{$pkgs{$v}}, $k;
$sizes{$v} += $pkg->size - $packages->{sizes}{$pkg->name};
}
log::l("pkgs::computeGroupSize took: ", formatTimeRaw(time() - $time));
log::l(sprintf "%s %dMB %s", $_, $sizes{$_} / sqr(1024), join(',', @{$pkgs{$_}})) foreach keys %sizes;
\%sizes, \%pkgs;
}
sub openInstallLog() {
my $f = "$::prefix/root/drakx/install.log";
open(my $LOG, ">> $f") ? log::l("opened $f") : log::l("Failed to open $f. No install log will be kept."); #-#
CORE::select((CORE::select($LOG), $| = 1)[0]);
URPM::rpmErrorWriteTo(fileno $LOG);
$LOG;
}
sub rpmDbOpen {
my ($o_rebuild_needed) = @_;
if ($o_rebuild_needed) {
if (my $pid = fork()) {
waitpid $pid, 0;
$? & 0xff00 and die "rebuilding of rpm database failed";
} else {
log::l("rebuilding rpm database");
my $rebuilddb_dir = "$::prefix/var/lib/rpmrebuilddb.$$";
-d $rebuilddb_dir and log::l("removing stale directory $rebuilddb_dir"), rm_rf($rebuilddb_dir);
URPM::DB::rebuild($::prefix) or log::l("rebuilding of rpm database failed: " . URPM::rpmErrorString()), c::_exit(2);
c::_exit(0);
}
}
my $db;
if ($db = URPM::DB::open($::prefix)) {
log::l("opened rpm database for examining existing packages");
} else {
log::l("unable to open rpm database, using empty rpm db emulation");
$db = new URPM;
}
$db;
}
sub rpmDbCleanLogs() {
unlink glob("$::prefix/var/lib/rpm/__db.*");
}
sub open_rpm_db_rw() {
my $db = URPM::DB::open($::prefix, 1);
$db and log::l("opened rpmdb for writing in $::prefix");
$db;
}
sub cleanOldRpmDb() {
my $failed;
foreach (qw(Basenames Conflictname Group Name Packages Providename Requirename Triggername)) {
-s "$::prefix/var/lib/rpm/$_" or $failed = 'failed';
}
#- rebuilding has been successfull, so remove old rpm database if any.
#- once we have checked the rpm4 db file are present and not null, in case
#- of doubt, avoid removing them...
unless ($failed) {
log::l("rebuilding rpm database completed successfully");
foreach (qw(conflictsindex.rpm fileindex.rpm groupindex.rpm nameindex.rpm packages.rpm
providesindex.rpm requiredby.rpm triggerindex.rpm)) {
-e "$::prefix/var/lib/rpm/$_" or next;
log::l("removing old rpm file $_");
rm_rf("$::prefix/var/lib/rpm/$_");
}
}
}
sub selectPackagesAlreadyInstalled {
my ($packages) = @_;
log::l("computing installed flags and size of installed packages");
$packages->{sizes} = $packages->compute_installed_flags($packages->{rpmdb});
}
sub selectPackagesToUpgrade {
my ($packages, $o_medium) = @_;
#- check before that if medium is given, it should be valid.
$o_medium && (! defined $o_medium->{start} || ! defined $o_medium->{end}) and return;
log::l("selecting packages to upgrade");
my $state = $packages->{state} ||= {};
$state->{selected} = {};
my %selection;
$packages->request_packages_to_upgrade($packages->{rpmdb}, $state, \%selection,
requested => undef,
$o_medium ? (start => $o_medium->{start}, end => $o_medium->{end}) : (),
);
log::l("resolving dependencies...");
$packages->resolve_requested($packages->{rpmdb}, $state, \%selection,
callback_choices => \&packageCallbackChoices);
log::l("...done");
}
sub allowedToUpgrade { $_[0] !~ /^(kernel|kernel22|kernel2.2|kernel-secure|kernel-smp|kernel-linus|kernel-linus2.2|hackkernel|kernel-enterprise)$/ }
sub supplCDMountPoint() { install_medium::by_id(1)->method eq 'cdrom' ? "/tmp/image" : "/mnt/cdrom" }
sub installTransactionClosure {
my ($packages, $id2pkg) = @_;
my ($id, %closure, @l, $medium, $min_id, $max_id);
@l = sort { $a <=> $b } keys %$id2pkg;
#- search first usable medium (sorted by medium ordering).
foreach (sort { $a->{start} <=> $b->{start} } values %{$packages->{mediums}}) {
next if ref $_ ne 'install_medium'; #- skip empty hash artifact
unless ($_->selected) {
#- this medium is not selected, but we have to make sure no package is left
#- in $id2pkg.
if (defined $_->{start} && defined $_->{end}) {
foreach ($_->{start} .. $_->{end}) {
delete $id2pkg->{$_};
}
@l = sort { $a <=> $b } keys %$id2pkg;
}
#- anyway, examine the next one.
next;
}
if ($l[0] <= $_->{end}) {
#- we have a candidate medium, it could be the right one containing
#- the first package of @l...
$l[0] >= $_->{start} and $medium = $_, last;
#- ... but it could be necessary to find the first
#- medium containing package of @l.
foreach my $id (@l) {
$id >= $_->{start} && $id <= $_->{end} and $medium = $_, last;
}
$medium and last;
}
}
$medium or return (); #- no more medium usable -> end of installation by returning empty list.
($min_id, $max_id) = ($medium->{start}, $medium->{end});
#- Supplementary CD : switch temporarily to "cdrom" method
my $suppl_CD = $medium->is_suppl_cd;
local $::o->{method} = do {
my $cdrom;
cat_("/proc/mounts") =~ m,(/dev/\S+)\s+(?:/mnt/cdrom|/tmp/image), and $cdrom = $1;
if (!defined $cdrom) {
(my $cdromdev) = detect_devices::cdroms();
$cdrom = $cdromdev->{device};
log::l("cdrom redetected at $cdrom");
devices::make($cdrom);
install_any::ejectCdrom($cdrom) if $::o->{method} eq 'cdrom';
install_any::mountCdrom(supplCDMountPoint(), $cdrom);
} else { log::l("cdrom already found at $cdrom") }
'cdrom';
} if $suppl_CD;
#- it is sure at least one package will be installed according to medium chosen.
install_any::useMedium($medium->{medium});
if (install_any::method_allows_medium_change($medium->method)) {
my $pkg = $packages->{depslist}[$l[0]];
#- force changeCD callback to be called from main process.
install_any::getFile($pkg->filename, $::o->{method}, $suppl_CD ? supplCDMountPoint() : undef);
#- close opened handle above.
install_any::getFile('XXX');
}
while (defined($id = shift @l)) {
my @l2 = $id;
while (defined($id = shift @l2)) {
exists $closure{$id} and next;
$id >= $min_id && $id <= $max_id or next;
$closure{$id} = undef;
my $pkg = $packages->{depslist}[$id];
foreach ($pkg->requires_nosense) {
foreach (keys %{$packages->{provides}{$_} || {}}) {
if ($id2pkg->{$_}) {
push @l2, $_;
last;
}
}
}
}
keys %closure >= $limitMinTrans and last;
}
map { delete $id2pkg->{$_} } grep { $id2pkg->{$_} } sort { $a <=> $b } keys %closure;
}
sub installCallback {
# my (undef, $msg, @para) = @_;
# log::l("$msg: " . join(',', @para));
}
sub install {
my ($isUpgrade, $toInstall, $packages, $callback) = @_;
my %packages;
delete $packages->{rpmdb}; #- make sure rpmdb is closed before.
#- avoid potential problems with rpm db personality change
rpmDbCleanLogs();
return if !@$toInstall;
#- for root loopback'ed /boot
my $loop_boot = fs::loopback::prepare_boot();
#- first stage to extract some important information
#- about the selected packages. This is used to select
#- one or many transactions.
my ($total, $nb);
foreach my $pkg (@$toInstall) {
$packages{$pkg->id} = $pkg;
$nb++;
$total += to_int($pkg->size); #- do not correct for upgrade!
}
log::l("pkgs::install $::prefix");
log::l("pkgs::install the following: ", join(" ", map { $_->name } values %packages));
URPM::read_config_files();
URPM::add_macro(join(' ', '__dbi_cdb', URPM::expand('%__dbi_cdb'), 'nofsync'));
my $LOG = openInstallLog();
#- do not modify/translate the message used with installCallback since
#- these are keys during progressing installation, or change in other
#- place (install_steps_gtk.pm,...).
$callback->($packages, user => undef, install => $nb, $total);
do {
my @transToInstall = installTransactionClosure($packages, \%packages);
$nb = values %packages;
#- added to exit typically after last media unselected.
if ($nb == 0 && scalar(@transToInstall) == 0) {
cleanHeaders();
fs::loopback::save_boot($loop_boot);
return;
}
#- extract headers for parent as they are used by callback.
extractHeaders(\@transToInstall, $packages->{mediums});
my $close = sub {
my ($pkg) = @_;
#- update flag associated to package.
$pkg->set_flag_installed(1);
$pkg->set_flag_upgrade(0);
#- update obsoleted entry.
my $rejected = $packages->{state}{rejected};
foreach (keys %$rejected) {
if (delete $rejected->{$_}{closure}{$pkg->fullname}) {
%{$rejected->{$_}{closure}} or delete $rejected->{$_};
}
}
};
my ($retry_pkg, $retry_count);
while ($retry_pkg || @transToInstall) {
if ($::testing) {
my $size_typical = $nb ? int($total/$nb) : 0;
foreach (@transToInstall) {
log::l("i would install ", $_->name, " now");
my $id = $_->id;
$callback->($packages, inst => $id, start => 0, $size_typical);
$callback->($packages, inst => $id, progress => 0, $size_typical);
$close->($_);
}
} else {
my $db = open_rpm_db_rw() or die "error opening RPM database: ", URPM::rpmErrorString();
my $trans = $db->create_transaction($::prefix);
if ($retry_pkg) {
log::l("opened rpm database for retry transaction of 1 package only");
$trans->add($retry_pkg, $isUpgrade && allowedToUpgrade($retry_pkg->name))
or log::l("add failed for " . $retry_pkg->fullname);
} else {
log::l("opened rpm database for transaction of " . int(@transToInstall) .
" new packages, still $nb after that to do");
$trans->add($_, $isUpgrade && allowedToUpgrade($_->name))
foreach @transToInstall;
}
my @checks = $trans->check; @checks and log::l("check failed : " . join("\n ", @checks));
$trans->order or die "error ordering package list: " . URPM::rpmErrorString();
$trans->set_script_fd(fileno $LOG);
log::l("rpm transactions start");
my $fd; #- since we return the "fileno", perl does not know we're still using it, and so closes it, and :-(
my @probs = $trans->run($packages, force => 1, nosize => 1, callback_open => sub {
my ($packages, $_type, $id) = @_;
my $pkg = defined $id && $packages->{depslist}[$id];
my $medium = packageMedium($packages, $pkg);
my $f = $pkg && $pkg->filename;
print $LOG "$f\n";
if ($medium->is_suppl_cd) {
$fd = install_any::getFile($f, $::o->{method}, supplCDMountPoint());
} else {
$fd = install_any::getFile($f, $::o->{method}, $medium->{prefix});
}
$fd ? fileno $fd : -1;
}, callback_close => sub {
my ($packages, $_type, $id) = @_;
my $pkg = defined $id && $packages->{depslist}[$id] or return;
my $check_installed;
$db->traverse_tag('name', [ $pkg->name ], sub {
my ($p) = @_;
$check_installed ||= $pkg->compare_pkg($p) == 0;
});
$check_installed or log::l($pkg->name . " not installed, " . URPM::rpmErrorString());
$check_installed and $close->($pkg);
}, callback_inst => $callback,
);
log::l("transactions done, now trying to close still opened fd");
install_any::getFile('XXX'); #- close still opened fd.
@probs and die "installation of rpms failed:\n ", join("\n ", @probs);
}
#- if we are using a retry mode, this means we have to split the transaction with only
#- one package for each real transaction.
if (!$retry_pkg) {
my @badPackages;
foreach (@transToInstall) {
if (!$_->flag_installed && packageMedium($packages, $_)->selected && !exists($ignoreBadPkg{$_->name})) {
push @badPackages, $_;
log::l("bad package " . $_->fullname);
} else {
$_->free_header;
}
}
@transToInstall = @badPackages;
#- if we are in retry mode, we have to fetch only one package at a time.
$retry_pkg = shift @transToInstall;
$retry_count = 3;
} else {
my $name;
if (!$retry_pkg->flag_installed && packageMedium($packages, $retry_pkg)->selected && !exists($ignoreBadPkg{$retry_pkg->name})) {
if ($retry_count) {
log::l("retrying installing package " . $retry_pkg->fullname . " alone in a transaction");
--$retry_count;
} else {
log::l("bad package " . $retry_pkg->fullname . " unable to be installed");
$retry_pkg->set_flag_requested(0);
$retry_pkg->set_flag_required(0);
#- keep name to display (problem of displaying ?).
$name = $retry_pkg->fullname;
$retry_pkg->free_header;
$retry_pkg = shift @transToInstall;
$retry_count = 3;
#- now it could be safe to display error message ?
cdie("error installing package list: $name");
}
}
#- check if name has been set (so that the following code has been executed already).
if (!$name && ($retry_pkg->flag_installed || !$retry_pkg->flag_selected)) {
$retry_pkg->free_header;
$retry_pkg = shift @transToInstall;
$retry_count = 3;
}
}
}
cleanHeaders();
} while $nb > 0 && !$pkgs::cancel_install;
log::l("closing install.log file");
close $LOG;
eval { fs::mount::umount("/mnt/cdrom") };
cleanHeaders();
fs::loopback::save_boot($loop_boot);
}
sub upgrade_by_removing_pkgs {
my ($packages, $callback, $extension, $upgrade_name) = @_;
my $upgrade_data;
if ($upgrade_name) {
my @l = glob("$ENV{SHARE_PATH}/upgrade/$upgrade_name*");
@l == 0 and log::l("upgrade_by_removing_pkgs: no special upgrade data");
@l > 1 and log::l("upgrade_by_removing_pkgs: many special upgrade data (" . join(' ', @l) . ")");
$upgrade_data = $l[0];
}
log::l("upgrade_by_removing_pkgs (extension=$extension, upgrade_data=$upgrade_data)");
#- put the release file in /root/drakx so that we continue an upgrade even if the file has gone
my $f = common::release_file($::prefix);
if (dirname($f) eq '/etc') {
output_p("$::prefix/root/drakx/" . basename($f) . '.upgrading', cat_("$::prefix$f"));
}
my $busy_var_tmp = "$::prefix/var/tmp/ensure-rpm-does-not-remove-this-dir";
touch($busy_var_tmp);
if ($upgrade_data) {
foreach (glob("$upgrade_data/pre.*")) {
my $f = '/tmp/' . basename($_);
cp_af($_, "$::prefix$f");
run_program::rooted($::prefix, $f);
unlink "$::prefix$f";
}
}
my @was_installed = remove_pkgs_to_upgrade($packages, $callback, $extension);
{
my @restore_files = qw(/etc/passwd /etc/group /etc/ld.so.conf);
foreach (@restore_files) {
rename "$::prefix$_.rpmsave", "$::prefix$_";
}
install_any::create_minimal_files();
unlink $busy_var_tmp;
}
my %map = map {
chomp;
my ($name, @new) = split;
$name => \@new;
} $upgrade_data ? cat_("$upgrade_data/map") : ();
log::l("upgrade_by_removing_pkgs: map $upgrade_data/map gave " . (int keys %map) . " rules");
my $log;
my @to_install = uniq(map {
$log .= " $_=>" . join('+', @{$map{$_}}) if $map{$_};
$map{$_} ? @{$map{$_}} : $_;
} @was_installed);
log::l("upgrade_by_removing_pkgs special maps:$log");
log::l("upgrade_by_removing_pkgs: wanted packages: ", join(' ', sort @to_install));
@to_install;
}
sub removed_pkgs_to_upgrade_file() { "$::prefix/root/drakx/removed_pkgs_to_upgrade" }
sub remove_pkgs_to_upgrade {
my ($packages, $callback, $extension) = @_;
my @to_remove;
my @was_installed;
{
$packages->{rpmdb} ||= pkgs::rpmDbOpen();
$packages->{rpmdb}->traverse(sub {
my ($pkg) = @_;
if ($pkg->release =~ /$extension$/) {
push @was_installed, $pkg->name;
push @to_remove, scalar $pkg->fullname;
}
});
}
if (-e removed_pkgs_to_upgrade_file()) {
log::l("removed_pkgs_to_upgrade: using saved installed packages list ", removed_pkgs_to_upgrade_file());
@was_installed = chomp_(cat_(removed_pkgs_to_upgrade_file()));
} else {
log::l("removed_pkgs_to_upgrade: saving (old) installed packages in ", removed_pkgs_to_upgrade_file());
output_p(removed_pkgs_to_upgrade_file(), map { "$_\n" } @was_installed);
}
delete $packages->{rpmdb}; #- make sure rpmdb is closed before.
remove(\@to_remove, $callback, noscripts => 1);
@was_installed;
}
sub remove_marked_ask_remove {
my ($packages, $callback) = @_;
my @to_remove = keys %{$packages->{state}{ask_remove}} or return;
delete $packages->{rpmdb}; #- make sure rpmdb is closed before.
#- we are not checking depends since it should come when
#- upgrading a system. although we may remove some functionalities ?
remove(\@to_remove, $callback, force => 1);
delete $packages->{state}{ask_remove}{$_} foreach @to_remove;
}
sub remove_raw {
my ($to_remove, $callback, %run_transaction_options) = @_;
log::l("removing: " . join(' ', @$to_remove));
URPM::read_config_files();
URPM::add_macro(URPM::expand('__dbi_cdb %__dbi_cdb nofsync'));
my $db = open_rpm_db_rw() or die "error opening RPM database: ", URPM::rpmErrorString();
my $trans = $db->create_transaction($::prefix);
#- stuff remove all packages that matches $p, not a problem since $p has name-version-release format.
$trans->remove($_) foreach @$to_remove;
$callback->($db, user => undef, remove => scalar @$to_remove);
$trans->run(undef, %run_transaction_options, callback_uninst => $callback);
}
sub remove {
my ($_to_remove, $_callback, %run_transaction_options) = @_;
my @pbs = &remove_raw;
if (@pbs && !$run_transaction_options{noscripts}) {
$run_transaction_options{noscripts} = 1;
@pbs = &remove_raw;
}
if (@pbs) {
die "removing of old rpms failed:\n ", join("\n ", @pbs);
}
}
sub selected_leaves {
my ($packages) = @_;
my $provides = $packages->{provides};
my @l = grep { $_->flag_requested || $_->flag_installed } @{$packages->{depslist}};
my %required_ids;
foreach (@l) {
foreach ($_->requires_nosense) {
my $h = $provides->{$_} or next;
my @provides = keys %$h;
$required_ids{$provides[0]} = 1 if @provides == 1;
}
}
[ map { $_->name } grep { !$required_ids{$_->id} } @l ];
}
sub naughtyServers_list {
my ($quiet) = @_;
my @_old_81 = qw(
freeswan
);
my @_old_82 = qw(
vnc-server
postgresql-server
);
my @_old_92 = qw(
postfix ypbind bind ibod
);
my @_removed_92 = qw(
mcserv
samba
lpr
);
my @_moved_to_contrib_92 = qw(
boa
LPRng
wu-ftpd
am-utils
);
my @new_80 = qw(
jabber
am-utils
boa
cups
drakxtools-http
finger-server
imap
leafnode
ntp
openssh-server
pidentd
proftpd
rwall
squid
webmin
wu-ftpd
);
my @new_81 = qw(
ftp-server-krb5
telnet-server-krb5
ypserv
);
my @new_82 = qw(
LPRng
inn
netatalk
nfs-utils
rusers-server
samba-swat
tftp-server
ucd-snmp
);
my @new_92 = qw(
clusternfs
gkrellm-server
lisa
mon
net-snmp
openldap-servers
samba-server
saned
vsftpd
);
my @new_2006 = qw(
apache-conf
bpalogin
cfengine-cfservd
freeradius
mDNSResponder
openslp
pxe
routed
sendmail
spamassassin-spamd
);
my @not_warned = qw(
nfs-utils-clients
portmap
howl
); # X server
(@new_80, @new_81, @new_82, @new_92, @new_2006, if_(!$quiet, @not_warned));
}
sub naughtyServers {
my ($packages) = @_;
grep {
my $p = packageByName($packages, $_);
$p && $p->flag_selected;
} naughtyServers_list('quiet');
}
package install_medium;
use strict;
#- list of fields :
#- descr (text description)
#- end (last rpm id)
#- fakemedium ("$descr ($method$medium_name)", used locally by urpmi)
#- hdlist
#- hdlist_size
#- ignored
#- issuppl (is a supplementary media)
#- key_ids (hashref, values are key ids)
#- medium (number of the medium)
#- method
#- prefix
#- finalprefix (for install_urpmi)
#- pubkey
#- rpmsdir
#- selected
#- start (first rpm id)
#- synthesis_hdlist_size
#- update (for install_urpmi)
#- with_hdlist (for install_urpmi)
#- create a new medium
sub new { my ($class, %h) = @_; bless \%h, $class }
#- retrieve medium by id (usually a number) or an empty placeholder
sub by_id {
my ($medium_id, $o_packages) = @_;
$o_packages = $::o->{packages} unless defined $o_packages;
defined $o_packages->{mediums}{$medium_id}
? $o_packages->{mediums}{$medium_id}
#- if the medium is not known, return a placeholder
: bless { invalid => 1, medium => $medium_id };
}
#- is this medium a supplementary medium ?
sub is_suppl { my ($self) = @_; $self->{issuppl} }
sub mark_suppl { my ($self) = @_; $self->{issuppl} = 1 }
#- is this medium a supplementary CD ?
sub is_suppl_cd { my ($self) = @_; $self->{method} eq 'cdrom' && $self->is_suppl }
sub method {
my ($self) = @_;
$self->{method};
}
sub selected { my ($self) = @_; $self->{selected} }
sub select { my ($self) = @_; $self->{selected} = 1 }
#- unselect, keep it mind it was unselected
sub refuse { my ($self) = @_; $self->{selected} = undef }
#- XXX this function seems to be obsolete
sub ignored { my ($self) = @_; $self->{ignored} }
#- guess the CD number for this media.
#- XXX lots of heuristics here, must design this properly
sub get_cd_number {
my ($self) = @_;
my $description = $self->{descr};
(my $cd) = $description =~ /\b(?:CD|DVD) ?(\d+)\b/i;
if (!$cd) { #- test for single unnumbered DVD
$cd = 1 if $description =~ /\bDVD\b/i;
}
if (!$cd) { #- test for mini-ISO
$cd = 1 if $description =~ /\bmini.?cd\b/i;
}
#- don't mix suppl. cds with regular ones
if ($description =~ /suppl/i) { $cd += 100 }
$cd;
}
1;
Arabic', 'ar_EG', ' 23 ', 'utf_ar' ],
'as' => [ 'Assamese', 'ZZ Assamese', 'as_IN', ' 2 ', 'utf_bn' ],
'az' => [ 'Azeri (Latin)', 'Azerbaycanca', 'az_AZ', ' 2 ', 'utf_az' ],
'be' => [ 'Belarussian', 'Belaruskaya', 'be_BY', '1 ', 'cp1251' ],
'bg' => [ 'Bulgarian', 'Blgarski', 'bg_BG', '1 ', 'cp1251' ],
'bn' => [ 'Bengali', 'ZZ Bengali', 'bn_BD', ' 2 ', 'utf_bn' ],
'br' => [ 'Britton', 'Brezhoneg', 'br_FR', '1 ', 'iso-8859-15', 'br:fr_FR:fr' ],
'bs' => [ 'Bosnian', 'Bosanski', 'bs_BA', '1 ', 'iso-8859-2' ],
'ca' => [ 'Catalan', 'Catala', 'ca_ES', '1 ', 'iso-8859-15', 'ca:es_ES:es' ],
'cs' => [ 'Czech', 'Cestina', 'cs_CZ', '1 ', 'iso-8859-2' ],
'cy' => [ 'Welsh', 'Cymraeg', 'cy_GB', '1 ', 'utf_lat8', 'cy:en_GB:en' ],
'da' => [ 'Danish', 'Dansk', 'da_DK', '1 ', 'iso-8859-15' ],
'de' => [ 'German', 'Deutsch', 'de_DE', '1 ', 'iso-8859-15' ],
#-'dz' => [ 'Buthanese', 'ZZ Dzhonka', 'dz_BT', ' 2 ', 'unicode' ],
'el' => [ 'Greek', 'Ellynika', 'el_GR', '1 ', 'iso-8859-7' ],
'en_GB' => [ 'English', 'English', 'en_GB', '12345', 'iso-8859-15' ],
'en_US' => [ 'English (American)', 'English (American)', 'en_US', ' 5', 'C' ],
'en_IE' => [ 'English (Ireland)', 'English (Ireland)', 'en_IE', '1 ', 'iso-8859-15', 'en_IE:en_GB:en' ],
'eo' => [ 'Esperanto', 'Esperanto', 'eo_XX', '12345', 'unicode' ],
'es' => [ 'Spanish', 'Espanol', 'es_ES', '1 3 5', 'iso-8859-15' ],
'et' => [ 'Estonian', 'Eesti', 'et_EE', '1 ', 'iso-8859-15' ],
'eu' => [ 'Euskara (Basque)', 'Euskara', 'eu_ES', '1 ', 'iso-8859-15' ],
'fa' => [ 'Farsi (Iranian)', 'AA Farsi', 'fa_IR', ' 2 ', 'utf_ar' ],
'fi' => [ 'Finnish (Suomi)', 'Suomi', 'fi_FI', '1 ', 'iso-8859-15' ],
'fo' => [ 'Faroese', 'Foroyskt', 'fo_FO', '1 ', 'iso-8859-1' ],
'fr' => [ 'French', 'Francais', 'fr_FR', '1 345', 'iso-8859-15' ],
'ga' => [ 'Gaelic (Irish)', 'Gaeilge', 'ga_IE', '1 ', 'iso-8859-15', 'ga:en_IE:en_GB:en' ],
#'gd' => [ 'Gaelic (Scottish)', 'Gaidhlig', 'gd_GB', '1 ', 'utf_lat8', 'gd:en_GB:en' ],
'gl' => [ 'Galician', 'Galego', 'gl_ES', '1 ', 'iso-8859-15', 'gl:es_ES:es:pt:pt_BR' ],
'gu' => [ 'Gujarati', 'ZZ Gujarati', 'gu_IN', ' 2 ', 'unicode' ],
#'gv' => [ 'Gaelic (Manx)', 'Gaelg', 'gv_GB', '1 ', 'utf_lat8', 'gv:en_GB:en' ],
'he' => [ 'Hebrew', 'AA Ivrit', 'he_IL', ' 2 ', 'utf_he' ],
'hi' => [ 'Hindi', 'ZZ Hindi', 'hi_IN', ' 2 ', 'unicode' ],
'hr' => [ 'Croatian', 'Hrvatski', 'hr_HR', '1 ', 'iso-8859-2' ],
'hu' => [ 'Hungarian', 'Magyar', 'hu_HU', '1 ', 'iso-8859-2' ],
'hy' => [ 'Armenian', 'ZZ Armenian', 'hy_AM', ' 2 ', 'utf_hy' ],
# locale not done yet
#'ia' => [ 'Interlingua', 'Interlingua', 'ia_XX', '1 5', 'utf8' ],
'id' => [ 'Indonesian', 'Bahasa Indonesia', 'id_ID', ' 2 ', 'iso-8859-1' ],
'is' => [ 'Icelandic', 'Islenska', 'is_IS', '1 ', 'iso-8859-1' ],
'it' => [ 'Italian', 'Italiano', 'it_IT', '1 ', 'iso-8859-15' ],
#-'iu' => [ 'Inuktitut', 'ZZ Inuktitut', 'iu_CA', ' 5', 'utf_iu' ],
'ja' => [ 'Japanese', 'ZZ Nihongo', 'ja_JP', ' 2 ', 'jisx0208' ],
'ka' => [ 'Georgian', 'ZZ Georgian', 'ka_GE', ' 2 ', 'utf_ka' ],
#-'kl' => [ 'Greenlandic (inuit)', 'ZZ Inuit', 'kl_GL', ' 5', 'iso-8859-1' ],
'kn' => [ 'Kannada', 'ZZ Kannada', 'kn_IN', ' 2 ', 'utf_kn' ],
'ko' => [ 'Korean', 'ZZ Korea', 'ko_KR', ' 2 ', 'ksc5601' ],
'ku' => [ 'Kurdish', 'Kurdi', 'ku_TR', ' 2 ', 'iso-8859-9' ],
#-'kw' => [ 'Cornish', 'Kernewek', 'kw_GB', '1 ', 'utf_lat8', 'kw:en_GB:en' ],
'li' => [ 'Limbourgish', 'Limburgs', 'li_NL', '1 ', 'iso-8859-15' ],
'lo' => [ 'Laotian', 'Laotian', 'lo_LA', ' 2 ', 'utf_lo' ],
'lt' => [ 'Lithuanian', 'Lietuviskai', 'lt_LT', '1 ', 'iso-8859-13' ],
'lv' => [ 'Latvian', 'Latviesu', 'lv_LV', '1 ', 'iso-8859-13' ],
'mi' => [ 'Maori', 'Maori', 'mi_NZ', ' 4 ', 'unicode' ],
'mk' => [ 'Macedonian', 'Makedonski', 'mk_MK', '1 ', 'utf_cyr1' ],
'ml' => [ 'Malayalam', 'ZZ Malayalam', 'ml_IN', ' 2 ', 'unicode' ],
'mn' => [ 'Mongolian', 'Mongol', 'mn_MN', ' 2 ', 'utf_cyr2' ],
'mr' => [ 'Marathi', 'ZZ Marathi', 'mr_IN', ' 2 ', 'unicode' ],
'ms' => [ 'Malay', 'Bahasa Melayu', 'ms_MY', ' 2 ', 'iso-8859-1' ],
'mt' => [ 'Maltese', 'Maltin', 'mt_MT', '1 3 ', 'unicode' ],
'nb' => [ 'Norwegian Bokmaal', 'Norsk, Bokmal', 'nb_NO', '1 ', 'iso-8859-1', 'nb:no' ],
#'nds' => [ 'Low Saxon', 'Platduutsch', 'nds_DE', '1 ', 'iso-8859-1' ],
'ne' => [ 'Nepali', 'ZZ Nepali', 'ne_NP', ' 2 ', 'unicode' ],
'nl' => [ 'Dutch', 'Nederlands', 'nl_NL', '1 ', 'iso-8859-15' ],
'nn' => [ 'Norwegian Nynorsk', 'Norsk, Nynorsk', 'nn_NO', '1 ', 'iso-8859-1', 'nn:no@nynorsk:no_NY:no:nb' ],
'oc' => [ 'Occitan', 'Occitan', 'oc_FR', '1 ', 'iso-8859-1', 'oc:fr_FR:fr' ],
#-'ph' => [ 'Pilipino', 'Pilipino', 'ph_PH', ' 2 ', 'iso-8859-1', 'ph:tl' ],
'pl' => [ 'Polish', 'Polski', 'pl_PL', '1 ', 'iso-8859-2' ],
'pt' => [ 'Portuguese', 'Portugues', 'pt_PT', '1 3 ', 'iso-8859-15', 'pt_PT:pt:pt_BR' ],
'pt_BR' => [ 'Portuguese Brazil', 'Portugues do Brasil', 'pt_BR', ' 5', 'iso-8859-1', 'pt_BR:pt_PT:pt' ],
'ro' => [ 'Romanian', 'Romana', 'ro_RO', '1 ', 'iso-8859-2' ],
'ru' => [ 'Russian', 'Russkij', 'ru_RU', '12 ', 'koi8-u' ],
'se' => [ 'Saami', 'Samegiella', 'se_NO', '1 ', 'unicode' ],
'sk' => [ 'Slovak', 'Slovencina', 'sk_SK', '1 ', 'iso-8859-2' ],
'sl' => [ 'Slovenian', 'Slovenscina', 'sl_SI', '1 ', 'iso-8859-2' ],
'sq' => [ 'Albanian', 'Shqip', 'sq_AL', '1 ', 'iso-8859-1' ],
'sr' => [ 'Serbian Cyrillic', 'Srpska', 'sr_CS', '1 ', 'utf_cyr1', 'sp:sr' ],
'sr@Latn' => [ 'Serbian Latin', 'Srpska', 'sr_CS', '1 ', 'unicode', 'sh:sr@Latn' ],
#- ss_ZA not yet done, using en_ZA locale instead
'ss' => [ 'Swati', 'SiSwati', 'en_ZA', ' 3 ', 'iso-8859-1', 'ss:en_ZA' ],
'st' => [ 'Sotho', 'Sesotho', 'st_ZA', ' 3 ', 'iso-8859-1', 'st:nso:en_ZA' ],
'sv' => [ 'Swedish', 'Svenska', 'sv_SE', '1 ', 'iso-8859-1' ],
'ta' => [ 'Tamil', 'ZZ Tamil', 'ta_IN', ' 2 ', 'utf_ta' ],
'te' => [ 'Telugu', 'ZZ Telugu', 'te_IN', ' 2 ', 'unicode' ],
'tg' => [ 'Tajik', 'Tojiki', 'tg_TJ', ' 2 ', 'utf_cyr2' ],
'th' => [ 'Thai', 'ZZ Thai', 'th_TH', ' 2 ', 'tis620' ],
'tr' => [ 'Turkish', 'Turkce', 'tr_TR', ' 2 ', 'iso-8859-9' ],
#-'tt' => [ 'Tatar', 'Tatar', 'tt_RU', ' 2 ', 'utf_cyr2' ],
'uk' => [ 'Ukrainian', 'Ukrayinska', 'uk_UA', '1 ', 'koi8-u' ],
#-'ur' => [ 'Urdu', 'AA Urdu', 'ur_PK', ' 2 ', 'utf_ar' ],
'uz@Latn' => [ 'Uzbek (latin)', 'Ozbekcha', 'uz_UZ', ' 2 ', 'utf_cyr2', 'uz@Latn:uz' ],
'uz' => [ 'Uzbek (cyrillic)', 'Ozbekcha', 'uz_UZ', ' 2 ', 'utf_cyr2', 'uz@Cyrl:uz' ],
#- ve_ZA not yet done, using en_ZA locale instead
've' => [ 'Venda', 'Venda', 'en_ZA', ' 3 ', 'iso-8859-1', 've:ven:en_ZA' ],
'vi' => [ 'Vietnamese', 'Tieng Viet', 'vi_VN', ' 2 ', 'utf_vi' ],
'wa' => [ 'Walon', 'Walon', 'wa_BE', '1 ', 'iso-8859-15', 'wa:fr_BE:fr' ],
#- locale not done yet
#'wen' => [ 'Sorbian', 'XX Sorbian', 'wen_XX', '1 ', 'iso-8859-1' ],
'xh' => [ 'Xhosa', 'IsiXhosa', 'xh_ZA', ' 3 ', 'iso-8859-1', 'xh:en_ZA' ],
'yi' => [ 'Yiddish', 'AA Yidish', 'yi_US', '1 5', 'utf_he' ],
'zh_CN' => [ 'Chinese Simplified', 'ZZ ZhongWen', 'zh_CN', ' 2 ', 'gb2312', 'zh_CN.GB2312:zh_CN:zh' ],
'zh_TW' => [ 'Chinese Traditional', 'ZZ ZhongWen', 'zh_TW', ' 2 ', 'Big5', 'zh_TW.Big5:zh_TW:zh_HK:zh' ],
'zu' => [ 'Zulu', 'IsiZulu', 'zu_ZA', ' 3 ', 'iso-8859-1', 'xh:en_ZA' ],
);
sub l2name { exists $langs{$_[0]} && $langs{$_[0]}[0] }
sub l2transliterated { exists $langs{$_[0]} && $langs{$_[0]}[1] }
sub l2locale { exists $langs{$_[0]} && $langs{$_[0]}[2] }
sub l2location {
my %geo = (1 => 'Europe', 2 => 'Asia', 3 => 'Africa', 4 => 'Oceania/Pacific', 5 => 'America');
map { if_($langs{$_[0]}[3] =~ $_, $geo{$_}) } 1..5;
}
sub l2charset { exists $langs{$_[0]} && $langs{$_[0]}[4] }
sub l2language { exists $langs{$_[0]} && $langs{$_[0]}[5] }
sub list_langs {
my (%options) = @_;
my @l = keys %langs;
$options{exclude_non_installed} ? grep { -e "/usr/share/locale/".l2locale($_)."/LC_CTYPE" } @l : @l;
}
sub text_direction_rtl() { N("default:LTR") eq "default:RTL" }
#- key: country name (that should be YY in xx_YY locale)
#- [0]: country name in natural language
#- [1]: default locale for that country
#- [2]: geographic groups that this country belongs to (for displaying
#- in the menu grouped in smaller lists), 1=Europe, 2=Asia, 3=Africa,
#- 4=Oceania&Pacific, 5=America (if you wonder, it's the order
#- used in the olympic flag)
#-
#- Note: for countries for which a glibc locale don't exist (yet) I tried to
#- put a locale that makes sense; and a '#' at the end of the line to show
#- the locale is not the "correct" one. 'en_US' is used when no good choice
#- is available.
my %countries = (
'AF' => [ N_("Afghanistan"), 'en_US', '2' ], #
'AD' => [ N_("Andorra"), 'ca_ES', '1' ], #
'AE' => [ N_("United Arab Emirates"), 'ar_AE', '2' ],
'AG' => [ N_("Antigua and Barbuda"), 'en_US', '5' ], #
'AI' => [ N_("Anguilla"), 'en_US', '5' ], #
'AL' => [ N_("Albania"), 'sq_AL', '1' ],
'AM' => [ N_("Armenia"), 'hy_AM', '2' ],
'AN' => [ N_("Netherlands Antilles"), 'en_US', '5' ], #
'AO' => [ N_("Angola"), 'pt_PT', '3' ], #
'AQ' => [ N_("Antarctica"), 'en_US', '4' ], #
'AR' => [ N_("Argentina"), 'es_AR', '5' ],
'AS' => [ N_("American Samoa"), 'en_US', '4' ], #
'AT' => [ N_("Austria"), 'de_AT', '1' ],
'AU' => [ N_("Australia"), 'en_AU', '4' ],
'AW' => [ N_("Aruba"), 'en_US', '5' ], #
'AZ' => [ N_("Azerbaijan"), 'az_AZ', '1' ],
'BA' => [ N_("Bosnia and Herzegovina"), 'bs_BA', '1' ],
'BB' => [ N_("Barbados"), 'en_US', '5' ], #
'BD' => [ N_("Bangladesh"), 'bn_BD', '2' ],
'BE' => [ N_("Belgium"), 'fr_BE', '1' ],
'BF' => [ N_("Burkina Faso"), 'en_US', '3' ], #
'BG' => [ N_("Bulgaria"), 'bg_BG', '1' ],
'BH' => [ N_("Bahrain"), 'ar_BH', '2' ],
'BI' => [ N_("Burundi"), 'en_US', '3' ], #
'BJ' => [ N_("Benin"), 'fr_FR', '3' ], #
'BM' => [ N_("Bermuda"), 'en_US', '5' ], #
'BN' => [ N_("Brunei Darussalam"), 'ar_EG', '2' ], #
'BO' => [ N_("Bolivia"), 'es_BO', '5' ],
'BR' => [ N_("Brazil"), 'pt_BR', '5' ],
'BS' => [ N_("Bahamas"), 'en_US', '5' ], #
'BT' => [ N_("Bhutan"), 'en_IN', '2' ], #
'BV' => [ N_("Bouvet Island"), 'en_US', '3' ], #
'BW' => [ N_("Botswana"), 'en_BW', '3' ],
'BY' => [ N_("Belarus"), 'be_BY', '1' ],
'BZ' => [ N_("Belize"), 'en_US', '5' ], #
'CA' => [ N_("Canada"), 'en_CA', '5' ],
'CC' => [ N_("Cocos (Keeling) Islands"), 'en_US', '4' ], #
'CD' => [ N_("Congo (Kinshasa)"), 'fr_FR', '3' ], #
'CF' => [ N_("Central African Republic"), 'fr_FR', '3' ], #
'CG' => [ N_("Congo (Brazzaville)"), 'fr_FR', '3' ], #
'CH' => [ N_("Switzerland"), 'de_CH', '1' ],
'CI' => [ N_("Cote d'Ivoire"), 'fr_FR', '3' ], #
'CK' => [ N_("Cook Islands"), 'en_US', '4' ], #
'CL' => [ N_("Chile"), 'es_CL', '5' ],
'CM' => [ N_("Cameroon"), 'fr_FR', '3' ], #
'CN' => [ N_("China"), 'zh_CN', '2' ],
'CO' => [ N_("Colombia"), 'es_CO', '5' ],
'CR' => [ N_("Costa Rica"), 'es_CR', '5' ],
'CU' => [ N_("Cuba"), 'es_DO', '5' ], #
'CV' => [ N_("Cape Verde"), 'pt_PT', '3' ], #
'CX' => [ N_("Christmas Island"), 'en_US', '4' ], #
'CY' => [ N_("Cyprus"), 'en_US', '1' ], #
'CZ' => [ N_("Czech Republic"), 'cs_CZ', '2' ],
'DE' => [ N_("Germany"), 'de_DE', '1' ],
'DJ' => [ N_("Djibouti"), 'en_US', '3' ], #
'DK' => [ N_("Denmark"), 'da_DK', '1' ],
'DM' => [ N_("Dominica"), 'en_US', '5' ], #
'DO' => [ N_("Dominican Republic"), 'es_DO', '5' ],
'DZ' => [ N_("Algeria"), 'ar_DZ', '3' ],
'EC' => [ N_("Ecuador"), 'es_EC', '5' ],
'EE' => [ N_("Estonia"), 'et_EE', '1' ],
'EG' => [ N_("Egypt"), 'ar_EG', '3' ],
'EH' => [ N_("Western Sahara"), 'ar_MA', '3' ], #
'ER' => [ N_("Eritrea"), 'ti_ER', '3' ],
'ES' => [ N_("Spain"), 'es_ES', '1' ],
'ET' => [ N_("Ethiopia"), 'am_ET', '3' ],
'FI' => [ N_("Finland"), 'fi_FI', '1' ],
'FJ' => [ N_("Fiji"), 'en_US', '4' ], #
'FK' => [ N_("Falkland Islands (Malvinas)"), 'en_GB', '5' ], #
'FM' => [ N_("Micronesia"), 'en_US', '4' ], #
'FO' => [ N_("Faroe Islands"), 'fo_FO', '1' ],
'FR' => [ N_("France"), 'fr_FR', '1' ],
'GA' => [ N_("Gabon"), 'fr_FR', '3' ], #
'GB' => [ N_("United Kingdom"), 'en_GB', '1' ],
'GD' => [ N_("Grenada"), 'en_US', '5' ], #
'GE' => [ N_("Georgia"), 'ka_GE', '2' ],
'GF' => [ N_("French Guiana"), 'fr_FR', '5' ], #
'GH' => [ N_("Ghana"), 'en_GB', '3' ], #
'GI' => [ N_("Gibraltar"), 'en_GB', '1' ], #
'GL' => [ N_("Greenland"), 'kl_GL', '5' ],
'GM' => [ N_("Gambia"), 'en_US', '3' ], #
'GN' => [ N_("Guinea"), 'en_US', '3' ], #
'GP' => [ N_("Guadeloupe"), 'fr_FR', '5' ], #
'GQ' => [ N_("Equatorial Guinea"), 'en_US', '3' ], #
'GR' => [ N_("Greece"), 'el_GR', '1' ],
'GS' => [ N_("South Georgia and the South Sandwich Islands"), 'en_US', '4' ], #
'GT' => [ N_("Guatemala"), 'es_GT', '5' ],
'GU' => [ N_("Guam"), 'en_US', '4' ], #
'GW' => [ N_("Guinea-Bissau"), 'pt_PT', '3' ], #
'GY' => [ N_("Guyana"), 'en_US', '5' ], #
'HK' => [ N_("China (Hong Kong)"), 'zh_HK', '2' ],
'HM' => [ N_("Heard and McDonald Islands"), 'en_US', '4' ], #
'HN' => [ N_("Honduras"), 'es_HN', '5' ],
'HR' => [ N_("Croatia"), 'hr_HR', '1' ],
'HT' => [ N_("Haiti"), 'fr_FR', '5' ], #
'HU' => [ N_("Hungary"), 'hu_HU', '1' ],
'ID' => [ N_("Indonesia"), 'id_ID', '2' ],
'IE' => [ N_("Ireland"), 'en_IE', '1' ],
'IL' => [ N_("Israel"), 'he_IL', '2' ],
'IN' => [ N_("India"), 'hi_IN', '2' ],
'IO' => [ N_("British Indian Ocean Territory"), 'en_GB', '2' ], #
'IQ' => [ N_("Iraq"), 'ar_IQ', '2' ],
'IR' => [ N_("Iran"), 'fa_IR', '2' ],
'IS' => [ N_("Iceland"), 'is_IS', '1' ],
'IT' => [ N_("Italy"), 'it_IT', '1' ],
'JM' => [ N_("Jamaica"), 'en_US', '5' ], #
'JO' => [ N_("Jordan"), 'ar_JO', '2' ],
'JP' => [ N_("Japan"), 'ja_JP', '2' ],
'KE' => [ N_("Kenya"), 'en_ZW', '3' ], #
'KG' => [ N_("Kyrgyzstan"), 'en_US', '2' ], #
'KH' => [ N_("Cambodia"), 'en_US', '2' ], # km_KH not released yet
'KI' => [ N_("Kiribati"), 'en_US', '3' ], #
'KM' => [ N_("Comoros"), 'en_US', '2' ], #
'KN' => [ N_("Saint Kitts and Nevis"), 'en_US', '5' ], #
'KP' => [ N_("Korea (North)"), 'ko_KR', '2' ], #
'KR' => [ N_("Korea"), 'ko_KR', '2' ],
'KW' => [ N_("Kuwait"), 'ar_KW', '2' ],
'KY' => [ N_("Cayman Islands"), 'en_US', '5' ], #
'KZ' => [ N_("Kazakhstan"), 'ru_RU', '2' ], #
'LA' => [ N_("Laos"), 'lo_LA', '2' ],
'LB' => [ N_("Lebanon"), 'ar_LB', '2' ],
'LC' => [ N_("Saint Lucia"), 'en_US', '5' ], #
'LI' => [ N_("Liechtenstein"), 'de_CH', '1' ], #
'LK' => [ N_("Sri Lanka"), 'en_IN', '2' ], #
'LR' => [ N_("Liberia"), 'en_US', '3' ], #
'LS' => [ N_("Lesotho"), 'en_BW', '3' ], #
'LT' => [ N_("Lithuania"), 'lt_LT', '1' ],
'LU' => [ N_("Luxembourg"), 'de_LU', '1' ],
'LV' => [ N_("Latvia"), 'lv_LV', '1' ],
'LY' => [ N_("Libya"), 'ar_LY', '3' ],
'MA' => [ N_("Morocco"), 'ar_MA', '3' ],
'MC' => [ N_("Monaco"), 'fr_FR', '1' ], #
'MD' => [ N_("Moldova"), 'ro_RO', '1' ], #
'MG' => [ N_("Madagascar"), 'fr_FR', '3' ], #
'MH' => [ N_("Marshall Islands"), 'en_US', '4' ], #
'MK' => [ N_("Macedonia"), 'mk_MK', '1' ],
'ML' => [ N_("Mali"), 'en_US', '3' ], #
'MM' => [ N_("Myanmar"), 'en_US', '2' ], #
'MN' => [ N_("Mongolia"), 'mn_MN', '2' ],
'MP' => [ N_("Northern Mariana Islands"), 'en_US', '2' ], #
'MQ' => [ N_("Martinique"), 'fr_FR', '5' ], #
'MR' => [ N_("Mauritania"), 'en_US', '3' ], #
'MS' => [ N_("Montserrat"), 'en_US', '5' ], #
'MT' => [ N_("Malta"), 'mt_MT', '1' ],
'MU' => [ N_("Mauritius"), 'en_US', '3' ], #
'MV' => [ N_("Maldives"), 'en_US', '4' ], #
'MW' => [ N_("Malawi"), 'en_US', '3' ], #
'MX' => [ N_("Mexico"), 'es_MX', '5' ],
'MY' => [ N_("Malaysia"), 'ms_MY', '2' ],
'MZ' => [ N_("Mozambique"), 'pt_PT', '3' ], #
'NA' => [ N_("Namibia"), 'en_US', '3' ], #
'NC' => [ N_("New Caledonia"), 'fr_FR', '4' ], #
'NE' => [ N_("Niger"), 'en_US', '3' ], #
'NF' => [ N_("Norfolk Island"), 'en_GB', '4' ], #
'NG' => [ N_("Nigeria"), 'en_US', '3' ], #
'NI' => [ N_("Nicaragua"), 'es_NI', '5' ],
'NL' => [ N_("Netherlands"), 'nl_NL', '1' ],
'NO' => [ N_("Norway"), 'nb_NO', '1' ],
'NP' => [ N_("Nepal"), 'ne_NP', '2' ],
'NR' => [ N_("Nauru"), 'en_US', '4' ], #
'NU' => [ N_("Niue"), 'en_US', '4' ], #
'NZ' => [ N_("New Zealand"), 'en_NZ', '4' ],
'OM' => [ N_("Oman"), 'ar_OM', '2' ],
'PA' => [ N_("Panama"), 'es_PA', '5' ],
'PE' => [ N_("Peru"), 'es_PE', '5' ],
'PF' => [ N_("French Polynesia"), 'fr_FR', '4' ], #
'PG' => [ N_("Papua New Guinea"), 'en_NZ', '4' ], #
'PH' => [ N_("Philippines"), 'ph_PH', '2' ],
'PK' => [ N_("Pakistan"), 'ur_PK', '2' ],
'PL' => [ N_("Poland"), 'pl_PL', '1' ],
'PM' => [ N_("Saint Pierre and Miquelon"), 'fr_CA', '5' ], #
'PN' => [ N_("Pitcairn"), 'en_US', '4' ], #
'PR' => [ N_("Puerto Rico"), 'es_PR', '5' ],
'PS' => [ N_("Palestine"), 'ar_JO', '2' ], #
'PT' => [ N_("Portugal"), 'pt_PT', '1' ],
'PY' => [ N_("Paraguay"), 'es_PY', '5' ],
'PW' => [ N_("Palau"), 'en_US', '2' ], #
'QA' => [ N_("Qatar"), 'ar_QA', '2' ],
'RE' => [ N_("Reunion"), 'fr_FR', '2' ], #
'RO' => [ N_("Romania"), 'ro_RO', '1' ],
'RU' => [ N_("Russia"), 'ru_RU', '1' ],
'RW' => [ N_("Rwanda"), 'fr_FR', '3' ], #
'SA' => [ N_("Saudi Arabia"), 'ar_SA', '2' ],
'SB' => [ N_("Solomon Islands"), 'en_US', '4' ], #
'SC' => [ N_("Seychelles"), 'en_US', '4' ], #
'SD' => [ N_("Sudan"), 'ar_SD', '5' ],
'SE' => [ N_("Sweden"), 'sv_SE', '1' ],
'SG' => [ N_("Singapore"), 'en_SG', '2' ],
'SH' => [ N_("Saint Helena"), 'en_GB', '5' ], #
'SI' => [ N_("Slovenia"), 'sl_SI', '1' ],
'SJ' => [ N_("Svalbard and Jan Mayen Islands"), 'en_US', '1' ], #
'SK' => [ N_("Slovakia"), 'sk_SK', '1' ],
'SL' => [ N_("Sierra Leone"), 'en_US', '3' ], #
'SM' => [ N_("San Marino"), 'it_IT', '1' ], #
'SN' => [ N_("Senegal"), 'fr_FR', '3' ], #
'SO' => [ N_("Somalia"), 'en_US', '3' ], # so_SO
'SR' => [ N_("Suriname"), 'nl_NL', '5' ], #
'ST' => [ N_("Sao Tome and Principe"), 'en_US', '5' ], #
'SV' => [ N_("El Salvador"), 'es_SV', '5' ],
'SY' => [ N_("Syria"), 'ar_SY', '2' ],
'SZ' => [ N_("Swaziland"), 'en_BW', '3' ], #
'TC' => [ N_("Turks and Caicos Islands"), 'en_US', '5' ], #
'TD' => [ N_("Chad"), 'en_US', '3' ], #
'TF' => [ N_("French Southern Territories"), 'fr_FR', '4' ], #
'TG' => [ N_("Togo"), 'fr_FR', '3' ], #
'TH' => [ N_("Thailand"), 'th_TH', '2' ],
'TJ' => [ N_("Tajikistan"), 'tg_TJ', '2' ],
'TK' => [ N_("Tokelau"), 'en_US', '4' ], #
'TL' => [ N_("East Timor"), 'pt_PT', '4' ], #
'TM' => [ N_("Turkmenistan"), 'en_US', '2' ], #
'TN' => [ N_("Tunisia"), 'ar_TN', '5' ],
'TO' => [ N_("Tonga"), 'en_US', '3' ], #
'TR' => [ N_("Turkey"), 'tr_TR', '2' ],
'TT' => [ N_("Trinidad and Tobago"), 'en_US', '5' ], #
'TV' => [ N_("Tuvalu"), 'en_US', '4' ], #
'TW' => [ N_("Taiwan"), 'zh_TW', '2' ],
'TZ' => [ N_("Tanzania"), 'en_US', '3' ], #
'UA' => [ N_("Ukraine"), 'uk_UA', '1' ],
'UG' => [ N_("Uganda"), 'en_US', '3' ], # lug_UG
'UM' => [ N_("United States Minor Outlying Islands"), 'en_US', '5' ], #
'US' => [ N_("United States"), 'en_US', '5' ],
'UY' => [ N_("Uruguay"), 'es_UY', '5' ],
'UZ' => [ N_("Uzbekistan"), 'uz_UZ', '2' ],
'VA' => [ N_("Vatican"), 'it_IT', '1' ], #
'VC' => [ N_("Saint Vincent and the Grenadines"), 'en_US', '5' ],
'VE' => [ N_("Venezuela"), 'es_VE', '5' ],
'VG' => [ N_("Virgin Islands (British)"), 'en_GB', '5' ], #
'VI' => [ N_("Virgin Islands (U.S.)"), 'en_US', '5' ], #
'VN' => [ N_("Vietnam"), 'vi_VN', '2' ],
'VU' => [ N_("Vanuatu"), 'en_US', '4' ], #
'WF' => [ N_("Wallis and Futuna"), 'fr_FR', '4' ], #
'WS' => [ N_("Samoa"), 'en_US', '4' ], #
'YE' => [ N_("Yemen"), 'ar_YE', '2' ],
'YT' => [ N_("Mayotte"), 'fr_FR', '3' ], #
'CS' => [ N_("Serbia & Montenegro"), 'sr_CS', '1' ],
'ZA' => [ N_("South Africa"), 'en_ZA', '5' ],
'ZM' => [ N_("Zambia"), 'en_US', '3' ], #
'ZW' => [ N_("Zimbabwe"), 'en_ZW', '5' ],
);
sub c2name { exists $countries{$_[0]} && translate($countries{$_[0]}[0]) }
sub c2locale { exists $countries{$_[0]} && $countries{$_[0]}[1] }
sub list_countries {
my (%options) = @_;
my @l = keys %countries;
$options{exclude_non_installed} ? grep { -e "/usr/share/locale/".c2locale($_)."/LC_CTYPE" } @l : @l;
}
#- this list is built with the following command on the compile cluster:
#- rpm -qpl /cooker/RPMS/locales-* | grep LC_CTYPE | cut -d'/' -f5 | grep '_' | grep -v '\.' | sort | tr '\n' ' ' ; echo
our @locales = qw(ad_ET af_ZA am_ET an_ES ar_AE ar_BH ar_DZ ar_EG ar_IN ar_IQ ar_JO ar_KW ar_LB ar_LY ar_MA ar_OM ar_QA ar_SA ar_SD ar_SY ar_TN ar_YE as_IN az_AZ be_BY bg_BG bn_BD bn_IN br_FR bs_BA ca_ES cs_CZ cy_GB da_DK de_AT de_BE de_CH de_DE de_LU el_GR en_AU en_BE en_BW en_CA en_DK en_GB en_HK en_IE en_IN en_NZ en_PH en_SG en_US en_ZA en_ZW eo_XX es_AR es_BO es_CL es_CO es_CR es_DO es_EC es_ES es_GT es_HN es_MX es_NI es_PA es_PE es_PR es_PY es_SV es_US es_UY es_VE et_EE eu_ES fa_IR fi_FI fo_FO fr_BE fr_CA fr_CH fr_FR fr_LU ga_IE gd_GB gez_ER gez_ER@abegede gez_ET gez_ET@abegede gl_ES gu_IN gv_GB he_IL hi_IN hr_HR hu_HU hy_AM id_ID is_IS it_CH it_IT iu_CA ja_JP ka_GE kl_GL kn_IN ko_KR ku_TR kw_GB li_BE li_NL lo_LA lt_LT lv_LV mi_NZ mk_MK ml_IN mn_MN mr_IN ms_MY mt_MT nb_NO nds_DE nds_DE@traditional nds_NL ne_NP nl_BE nl_NL nn_NO oc_FR om_ET om_KE pa_IN ph_PH pl_PL pt_BR pt_PT qo_ET ro_RO ru_RU ru_UA se_NO sh_YU sid_ET sk_SK sl_SI sq_AL sr_CS sr_CS@Latn sr_YU sr_YU@Latn st_ZA sv_FI sv_SE sx_ET sz_ET ta_IN te_IN tg_TJ th_TH ti_ER ti_ET tig_ER tl_PH tr_TR tt_RU uk_UA ur_PK uz_UZ uz_UZ@Cyrl uz_UZ@Latn vi_VN wa_BE xh_ZA yi_US zh_CN zh_HK zh_SG zh_TW zu_ZA);
sub standard_locale {
my ($lang, $country, $prefer_lang) = @_;
retry:
member("${lang}_${country}", @locales) and return "${lang}_${country}";
$prefer_lang && member($lang, @locales) and return $lang;
length($lang) > 2 and $lang =~ s/^(..).*/$1/, goto retry;
}
sub fix_variant {
my ($locale) = @_;
#- uz@Cyrl_UZ -> uz_UZ@Cyrl
$locale =~ s/(.*)(\@\w+)(_.*)/$1$3$2/;
$locale;
}
sub getlocale_for_lang {
my ($lang, $country, $o_utf8) = @_;
fix_variant((standard_locale($lang, $country, 'prefer_lang') || l2locale($lang)) . ($o_utf8 ? '.UTF-8' : ''));
}
sub getlocale_for_country {
my ($lang, $country, $o_utf8) = @_;
fix_variant((standard_locale($lang, $country, '') || c2locale($country)) . ($o_utf8 ? '.UTF-8' : ''));
}
sub getLANGUAGE {
my ($lang, $o_country, $o_utf8) = @_;
l2language($lang) || join(':', uniq(getlocale_for_lang($lang, $o_country, $o_utf8), $lang, if_($lang =~ /^(..)_/, $1)));
}
my %xim = (
#- xcin only works with 'zh_TW', 'zh_TW.Big5', 'zh_CN', 'zh_CN.GB2312'
#- all other locale names, in particular 'zh_HK' or 'zh_TW.UTF-8'
#- are unknown to it. So chinput is used for all but 'zh_TW'
'zh_TW' => {
ENC => 'big5',
XIM => 'xcin',
XIM_PROGRAM => 'xcin',
XMODIFIERS => '"@im=xcin-zh_TW"',
GTK_IM_MODULE => 'xim',
CONSOLE_NOT_LOCALIZED => 'yes',
},
'zh_TW.UTF-8' => {
ENC => 'utf8',
XIM => 'Chinput',
XIM_PROGRAM => '"chinput -big5"',
XMODIFIERS => '"@im=Chinput"',
GTK_IM_MODULE => 'xim',
CONSOLE_NOT_LOCALIZED => 'yes',
},
'zh_CN' => {
ENC => 'gb',
XIM => 'Chinput',
XIM_PROGRAM => '"chinput -gb"',
XMODIFIERS => '"@im=Chinput"',
GTK_IM_MODULE => 'xim',
CONSOLE_NOT_LOCALIZED => 'yes',
},
'zh_CN.UTF-8' => {
ENC => 'utf8',
XIM => 'Chinput',
XIM_PROGRAM => '"chinput -gb"',
XMODIFIERS => '"@im=Chinput"',
GTK_IM_MODULE => 'xim',
CONSOLE_NOT_LOCALIZED => 'yes',
},
'zh_SG' => {
ENC => 'gb',
XIM => 'Chinput',
XIM_PROGRAM => '"chinput -gb"',
XMODIFIERS => '"@im=Chinput"',
GTK_IM_MODULE => 'xim',
CONSOLE_NOT_LOCALIZED => 'yes',
},
'zh_SG.UTF-8' => {
ENC => 'utf8',
XIM => 'Chinput',
XIM_PROGRAM => '"chinput -gb"',
XMODIFIERS => '"@im=Chinput"',
GTK_IM_MODULE => 'xim',
CONSOLE_NOT_LOCALIZED => 'yes',
},
'zh_HK' => {
ENC => 'big5',
XIM => 'Chinput',
XIM_PROGRAM => '"chinput -big5"',
XMODIFIERS => '"@im=Chinput"',
GTK_IM_MODULE => 'xim',
CONSOLE_NOT_LOCALIZED => 'yes',
},
'zh_HK.UTF-8' => {
ENC => 'utf8',
XIM => 'Chinput',
XIM_PROGRAM => '"chinput -big5"',
XMODIFIERS => '"@im=Chinput"',
GTK_IM_MODULE => 'xim',
CONSOLE_NOT_LOCALIZED => 'yes',
},
'ko_KR' => {
ENC => 'kr',
XIM => 'Ami',
#- NOTE: there are several possible versions of ami, for the different
#- desktops (kde, gnome, etc). So XIM_PROGRAM isn't defined; it will
#- be the xinitrc script, XIM section, that will choose the right one
#- XIM_PROGRAM => 'ami',
XMODIFIERS => '"@im=Ami"',
GTK_IM_MODULE => 'xim',
CONSOLE_NOT_LOCALIZED => 'yes',
},
'ko_KR.UTF-8' => {
ENC => 'utf8',
XIM => 'Ami',
#- NOTE: there are several possible versions of ami, for the different
#- desktops (kde, gnome, etc). So XIM_PROGRAM isn't defined; it will
#- be the xinitrc script, XIM section, that will choose the right one
#- XIM_PROGRAM => 'ami',
XMODIFIERS => '"@im=Ami"',
GTK_IM_MODULE => 'xim',
CONSOLE_NOT_LOCALIZED => 'yes',
},
'ja_JP' => {
ENC => 'eucj',
XIM => 'uim-anthy',
XIM_PROGRAM => 'uim-xim',
XMODIFIERS => '"@im=uim-anthy"',
GTK_IM_MODULE => 'uim-anthy',
},
'ja_JP.UTF-8' => {
ENC => 'utf8',
XIM => 'uim-anthy',
XIM_PROGRAM => 'uim-xim',
XMODIFIERS => '"@im=uim-anthy"',
GTK_IM_MODULE => 'uim-anthy',
},
#- XFree86 has an internal XIM for Thai that enables syntax checking etc.
#- 'Passthroug' is no check at all, 'BasicCheck' accepts bad sequences
#- and convert them to right ones, 'Strict' refuses bad sequences
'th_TH' => {
XIM_PROGRAM => '/bin/true', #- it's an internal module
XMODIFIERS => '"@im=BasicCheck"',
},
#- xvnkb is not an XIM input method; but an input method of another
#- kind, only XIM_PROGRAM needs to be defined
#- ! xvnkb doesn't work in UTF-8 !
#- 'vi_VN.VISCII' => {
#- XIM_PROGRAM => 'xvnkb',
#- },
);
#- [0]: console font name
#- [1]: sfm map for console font (if needed)
#- [2]: acm file for console font (none if utf8)
#- [3]: iocharset param for mount (utf8 if utf8)
#- [4]: codepage parameter for mount (none if utf8)
my %charsets = (
#- chinese needs special console driver for text mode
"Big5" => [ undef, undef, undef, "big5", "950" ],
"gb2312" => [ undef, undef, undef, "gb2312", "936" ],
"C" => [ "lat0-16", undef, "iso15", "iso8859-1", "850" ],
"iso-8859-1" => [ "lat1-16", undef, "iso01", "iso8859-1", "850" ],
"iso-8859-2" => [ "lat2-sun16", undef, "iso02", "iso8859-2", "852" ],
"iso-8859-5" => [ "UniCyr_8x16", undef, "iso05", "iso8859-5", "866" ],
"iso-8859-7" => [ "iso07.f16", undef, "iso07", "iso8859-7", "869" ],
"iso-8859-9" => [ "lat5u-16", undef, "iso09", "iso8859-9", "857" ],
"iso-8859-13" => [ "tlat7", undef, "iso13", "iso8859-13", "775" ],
"iso-8859-15" => [ "lat0-16", undef, "iso15", "iso8859-15", "850" ],
#- japanese needs special console driver for text mode [kon2]
"jisx0208" => [ undef, undef, "trivial.trans", "euc-jp", "932" ],
"koi8-r" => [ "UniCyr_8x16", undef, "koi8-r", "koi8-r", "866" ],
"koi8-u" => [ "UniCyr_8x16", undef, "koi8-u", "koi8-u", "866" ],
"cp1251" => [ "UniCyr_8x16", undef, "cp1251", "cp1251", "866" ],
#- korean needs special console driver for text mode
"ksc5601" => [ undef, undef, undef, "euc-kr", "949" ],
#- I have no console font for Thai...
"tis620" => [ undef, undef, "trivial.trans", "tis-620", "874" ],
# UTF-8 encodings here; they differ in the console font mainly.
"utf_am" => [ "Agafari-16", undef, undef, "utf8", undef ],
"utf_ar" => [ "iso06.f16", undef, undef, "utf8", undef ],
"utf_az" => [ "tiso09e", undef, undef, "utf8", undef ],
"utf_bn" => [ undef, undef, undef, "utf8", undef ],
"utf_cyr1" => [ "UniCyr_8x16", undef, undef, "utf8", undef ],
"utf_cyr2" => [ "koi8-k", undef, undef, "utf8", undef ],
"utf_he" => [ "iso08.f16", undef, undef, "utf8", undef ],
"utf_hy" => [ "arm8", undef, undef, "utf8", undef ],
"utf_ka" => [ "t_geors", undef, undef, "utf8", undef ],
"utf_kn" => [ undef, undef, undef, "utf8", undef ],
"utf_lo" => [ undef, undef, undef, "utf8", undef ],
"utf_ta" => [ "tamil", undef, undef, "utf8", undef ],
"utf_vi" => [ "tcvn8x16", undef, undef, "utf8", undef ],
"utf_lat8" => [ "iso14.f16", undef, undef, "utf8", undef ],
# default for utf-8 encodings
"unicode" => [ "LatArCyrHeb-16", undef, undef, "utf8", undef ],
);
#- for special cases not handled magically
my %charset2kde_charset = (
gb2312 => 'gb2312.1980-0',
jisx0208 => 'jisx0208.1983-0',
ksc5601 => 'ksc5601.1987-0',
Big5 => 'big5-0',
cp1251 => 'microsoft-cp1251',
utf8 => 'iso10646-1',
tis620 => 'tis620-0',
#- Tamil KDE translations still use TSCII, and KDE know it as iso-8859-1
utf_ta => 'iso8859-1',
);
my @during_install__lang_having_their_LC_CTYPE = qw(ja ko ta);
#- -------------------
sub list {
my (%options) = @_;
my @l = list_langs();
if ($options{exclude_non_installed_langs}) {
@l = grep { -e "/usr/share/locale/$_/LC_CTYPE" } @l;
}
@l;
}
sub l2console_font {
my ($locale, $during_install) = @_;
my $c = $charsets{l2charset($locale->{lang}) || return} or return;
my ($name, $sfm, $acm) = @$c;
undef $acm if $locale->{utf8} && !$during_install;
($name, $sfm, $acm);
}
sub get_kde_lang {
my ($locale, $o_default) = @_;
#- get it using
#- echo C $(rpm -qp --qf "%{name}\n" /RPMS/kde-i18n-* | sed 's/kde-i18n-//')
my @valid_kde_langs = qw(C af ar az be bg br bs ca cs cy da de el en_GB eo es et eu fa fi fo fr ga gl he hr hu id is it ja ko ku lo lt lv mi mk mn mt nb nl nn nso oc pl pt pt_BR ro ru se sk sl sr ss sv ta th tr uk uz ven vi wa wen xh zh_CN zh_TW zu);
my %valid_kde_langs; @valid_kde_langs{@valid_kde_langs} = ();
my $valid_lang = sub {
my ($lang) = @_;
#- fast & dirty solution to ensure bad entries do not happen
my %fixlangs = (en => 'C', en_US => 'C',
'sr@Latn' => 'sr',
st => 'nso', ve => 'ven',
zh_CN => 'zh_CN', zh_SG => 'zh_CN', zh_TW => 'zh_TW', zh_HK => 'zh_TW');
exists $fixlangs{$lang} ? $fixlangs{$lang} :
exists $valid_kde_langs{$lang} ? $lang :
exists $valid_kde_langs{substr($lang, 0, 2)} ? substr($lang, 0, 2) : '';
};
my $r;
$r ||= $valid_lang->($locale->{lang});
$r ||= find { $valid_lang->($_) } split(':', getlocale_for_lang($locale->{lang}, $locale->{country}));
$r || $o_default || 'C';
}
sub charset2kde_charset {
my ($charset, $o_default) = @_;
my $iocharset = ($charsets{$charset} || [])->[3];
my @valid_kde_charsets = qw(big5-0 gb2312.1980-0 iso10646-1 iso8859-1 iso8859-4 iso8859-6 iso8859-8 iso8859-13 iso8859-14 iso8859-15 iso8859-2 iso8859-3 iso8859-5 iso8859-7 iso8859-9 koi8-r koi8-u ksc5601.1987-0 jisx0208.1983-0 microsoft-cp1251 tis620-0);
my %valid_kde_charsets; @valid_kde_charsets{@valid_kde_charsets} = ();
my $valid_charset = sub {
my ($charset) = @_;
#- fast & dirty solution to ensure bad entries do not happen
exists $valid_kde_charsets{$charset} && $charset;
};
my $r;
$r ||= $valid_charset->($charset2kde_charset{$charset});
$r ||= $valid_charset->($charset2kde_charset{$iocharset});
$r ||= $valid_charset->($iocharset);
$r || $o_default || 'iso10646-1';
}
#- font+size for different charsets; the field [0] is the default,
#- others are overrridens for fixed(1), toolbar(2), menu(3) and taskbar(4)
my %charset2kde_font = (
'C' => [ "Sans,10", "Monospace,10" ],
'iso-8859-1' => [ "Sans,10", "Monospace,10" ],
'iso-8859-2' => [ "Sans,10", "Monospace,10" ],
'iso-8859-7' => [ "Helvetica,12", "courier,10", "Helvetica,11" ],
'iso-8859-9' => [ "Sans,10", "Monospace,10" ],
'iso-8859-15' => [ "Sans,10", "Monospace,10" ],
'iso-8859-13' => [ "Sans,10", "Monospace,10" ],
'jisx0208' => [ "Kochi Mincho,13", "Kochi Gothic,13" ],
'ksc5601' => [ "Baekmuk Gulim,16" ],
'gb2312' => [ "AR PL SungtiL GB,13" ],
'Big5' => [ "AR PL Mingti2L Big5,13" ],
'tis620' => [ "Norasi,16", "Norasi,15" ],
'utf_ar' => [ "Kacs_qr,14", "Courier New,13", "Kacs_qr,13" ],
'utf_am' => [ "GF Zemen Unicode,15" ],
'utf_az' => [ "Nimbus Sans,12", "Nimbus Mono,10", "Nimbus Sans,11" ],
'utf_bn' => [ "Mukti,14", ],
'utf_he' => [ "Nachlieli,13", , "Miriam Mono,10", "Nachlieli,11" ],
'utf_hy' => [ "Artsounk,12", "Monospace,10", "Artsounk,11" ],
'utf_kn' => [ "Sampige,14", ],
'utf_ta' => [ "TSCu_Paranar,14", "Tsc_avarangalfxd,10", "TSCu_Paranar,12", ],
#- the following should be changed to better defaults when better fonts
#- get available
'utf_vi' => [ "misc-fixed,13", "misc-fixed,13", "misc-fixed,10", ],
'utf_ka' => [ "clearlyu,15" ],
'utf_lo' => [ "clearlyu,15" ],
'default' => [ "Nimbus Sans,12", "Nimbus Mono,10", "Nimbus Sans,11" ],
);
sub charset2kde_font {
my ($charset, $type) = @_;
my $font = $charset2kde_font{$charset} || $charset2kde_font{default};
my $r = $font->[$type] || $font->[0];
#- the format is "font-name,size,-1,5,0,0,0,0,0,0" I have no idea of the
#- meaning of that "5"...
"$r,-1,5,0,0,0,0,0,0";
}
# this define pango name fonts (like "NimbusSans L") depending
# on the "charset" defined by language array. This allows to selecting
# an appropriate font for each language.
my %charset2pango_font = (
'tis620' => "Norasi 17",
'utf_ar' => "Kacst-Qr 14",
'utf_cyr2' => "Nimbus Sans L 12",
'utf_he' => "Sans 12",
'utf_hy' => "Artsounk 14",
'utf_ka' => "Sans 14",
'utf_lo' => "Sans 14",
'utf_ta' => "TSCu_Paranar 14",
'utf_vi' => "Sans 14",
'iso-8859-7' => "Kerkis 14",
'jisx0208' => "Sans 18",
#- Nimbus Sans L is missing some chars used by some cyrillic languages,
#- but tose haven't yet DrakX translations; it also misses vietnamese
#- latin chars; all other latin and cyrillic are covered.
'default' => "Nimbus Sans L 12"
);
sub charset2pango_font {
my ($charset) = @_;
$charset2pango_font{exists $charset2pango_font{$charset} ? $charset : 'default'};
}
sub l2pango_font {
my ($lang) = @_;
my $charset = l2charset($lang) or log::l("no charset found for lang $lang!"), return;
my $font = charset2pango_font($charset);
log::l("lang:$lang charset:$charset font:$font sfm:$charsets{$charset}[0]");
if (common::usingRamdisk()) {
if ($charsets{$charset}[0] !~ /lat|koi|UniCyr/) {
install_any::remove_bigseldom_used();
unlink glob_('/usr/share/langs/*'); #- remove langs images
my @generic_fontfiles = qw(/usr/X11R6/lib/X11/fonts/12x13mdk.pcf.gz /usr/X11R6/lib/X11/fonts/18x18mdk.pcf.gz);
#- need to unlink first because the files actually exist (and are void); they must exist
#- because if not, when gtk starts, pango will recompute its cache file and exclude them
unlink($_), install_any::getAndSaveFile($_) foreach @generic_fontfiles;
}
my %pango_modules = (arabic => 'ar|fa|ur', hangul => 'ko', hebrew => 'he|yi', indic => 'hi|bn|ta|te|mr', thai => 'th');
foreach my $module (keys %pango_modules) {
next if $lang !~ /$pango_modules{$module}/;
install_any::remove_bigseldom_used();
my ($pango_modules_dir) = glob('/usr/lib/pango/*/modules');
install_any::getAndSaveFile("$pango_modules_dir/pango-$module-xft.so");
}
}
return $font;
}
sub set {
my ($locale, $b_translate_for_console) = @_;
if ($::move) {
put_in_hash(\%ENV, i18n_env($locale));
return;
}
my ($lang) = $locale->{lang};
exists $langs{$lang} or log::l("lang::set: trying to set to $lang but I don't know it!"), return;
my $dir = "$ENV{SHARE_PATH}/locale";
if (!-e "$dir/$lang" && common::usingRamdisk()) {
@ENV{qw(LANG LC_ALL LANGUAGE LINGUAS)} = ();
my @LCs = qw(LC_ADDRESS LC_COLLATE LC_IDENTIFICATION LC_MEASUREMENT LC_MONETARY LC_NAME LC_NUMERIC LC_PAPER LC_TELEPHONE LC_TIME);
my $charset = during_install__l2charset($lang) || $lang;
#- there are 3 main charsets containing everything for all locales, except LC_CTYPE
#- by default, there is UTF-8.
#- when asked for GB2312 or BIG5, removing the other main charsets
my $main_charset = member($charset, 'GB2312', 'BIG5') ? $charset : 'UTF-8';
#- removing everything
#- except in main charset: only removing LC_CTYPE if it is there
eval { rm_rf($_ eq $main_charset ? "$dir/$_/LC_CTYPE" : "$dir/$_") } foreach all($dir);
if (!-e "$dir/$main_charset") {
#- getting the main charset
mkdir "$dir/$main_charset";
mkdir "$dir/$main_charset/LC_MESSAGES";
install_any::getAndSaveFile("$dir/$main_charset/$_") foreach @LCs, 'LC_MESSAGES/SYS_LC_MESSAGES';
}
mkdir "$dir/$lang";
#- linking to the main charset
symlink "../$main_charset/$_", "$dir/$lang/$_" foreach @LCs, 'LC_MESSAGES';
#- getting LC_CTYPE (putting it directly in $lang)
install_any::getAndSaveFile("Mandrake/mdkinst$dir/$charset/LC_CTYPE", "$dir/$lang/LC_CTYPE");
}
#- set all LC_* variables to a unique locale ("C"), and only redefine
#- LC_CTYPE (for X11 choosing the fontset) and LANGUAGE (for the po files)
$ENV{$_} = 'C' foreach qw(LC_NUMERIC LC_TIME LC_COLLATE LC_MONETARY LC_PAPER LC_NAME LC_ADDRESS LC_TELEPHONE LC_MEASUREMENT LC_IDENTIFICATION);
$ENV{LC_CTYPE} = $lang;
$ENV{LC_MESSAGES} = $lang;
$ENV{LANG} = $lang;
if ($b_translate_for_console && $lang =~ /^(ko|ja|zh|th)/) {
log::l("not translating in console");
$ENV{LANGUAGE} = 'C';
} else {
$ENV{LANGUAGE} = getLANGUAGE($lang);
}
load_mo();
$lang;
}
sub langs {
my ($l) = @_;
$l->{all} ? list_langs() : grep { $l->{$_} } keys %$l;
}
sub langsLANGUAGE {
my ($l, $o_c) = @_;
uniq(map { split ':', getLANGUAGE($_, $o_c) } langs($l));
}
sub utf8_should_be_needed {
my ($locale) = @_;
l2charset($locale->{lang}) =~ /utf|unicode/
|| uniq(grep { $_ ne 'C' } map { l2charset($_) } langs($locale->{langs})) > 1;
}
sub pack_langs {
my ($l) = @_;
my $s = $l->{all} ? 'all' : join ':', uniq(map { getLANGUAGE($_) } langs($l));
$ENV{RPM_INSTALL_LANG} = $s;
$s;
}
sub system_locales_to_ourlocale {
my ($locale_lang, $locale_country) = @_;
my $locale = {};
my $variant = $locale_lang =~ s/(\@\w+)// && $1;
my $locale_lang_no_encoding = $locale_lang =~ /(.*)\./ ? $1 : $locale_lang;
if (member($locale_lang_no_encoding, list_langs())) {
#- special lang's such as en_US pt_BR
$locale->{lang} = $locale_lang_no_encoding;
} else {
($locale->{lang}) = $locale_lang =~ /^(..)/;
}
$locale->{lang} .= $variant;
($locale->{country}) = $locale_country =~ /^.._(..)/;
$locale->{utf8} = $locale_lang =~ /UTF-8/;
#- safe fallbacks
$locale->{lang} ||= 'en_US';
$locale->{country} ||= 'US';
$locale;
}
sub read {
my ($prefix, $user_only) = @_;
my ($f1, $f2) = ("$prefix$ENV{HOME}/.i18n", "$prefix/etc/sysconfig/i18n");
my %h = getVarsFromSh($user_only && -e $f1 ? $f1 : $f2);
system_locales_to_ourlocale($h{LC_MESSAGES} || 'en_US', $h{LC_MONETARY} || 'en_US');
}
sub write_langs {
my ($prefix, $langs) = @_;
my $s = pack_langs($langs);
symlink "$prefix/etc/rpm", "/etc/rpm" if $prefix;
substInFile { s/%_install_langs.*//; $_ .= "%_install_langs $s\n" if eof && $s } "$prefix/etc/rpm/macros";
}
sub i18n_env {
my ($locale) = @_;
my $locale_lang = getlocale_for_lang($locale->{lang}, $locale->{country}, $locale->{utf8});
my $locale_country = getlocale_for_country($locale->{lang}, $locale->{country}, $locale->{utf8});
my $h = {
XKB_IN_USE => '',
(map { $_ => $locale_lang } qw(LANG LC_COLLATE LC_CTYPE LC_MESSAGES LC_TIME)),
LANGUAGE => getLANGUAGE($locale->{lang}, $locale->{country}, $locale->{utf8}),
(map { $_ => $locale_country } qw(LC_NUMERIC LC_MONETARY LC_ADDRESS LC_MEASUREMENT LC_NAME LC_PAPER LC_IDENTIFICATION LC_TELEPHONE))
};
log::l("lang::write: lang:$locale->{lang} country:$locale->{country} locale|lang:$locale_lang locale|country:$locale_country language:$h->{LANGUAGE}");
$h;
}
sub write {
my ($prefix, $locale, $b_user_only, $b_dont_touch_kde_files) = @_;
$locale && $locale->{lang} or return;
my $h = i18n_env($locale);
my ($name, $sfm, $acm) = l2console_font($locale, 0);
if ($name && !$b_user_only) {
my $p = "$prefix/usr/lib/kbd";
if ($name) {
eval {
my $font = "$p/consolefonts/$name.psf";
$font .= ".gz" if ! -e $font;
cp_af($font, "$prefix/etc/sysconfig/console/consolefonts");
add2hash $h, { SYSFONT => $name };
};
$@ and log::l("missing console font $name");
}
if ($sfm) {
eval {
cp_af(glob_("$p/consoletrans/$sfm*"), "$prefix/etc/sysconfig/console/consoletrans");
add2hash $h, { UNIMAP => $sfm };
};
$@ and log::l("missing console unimap file $sfm");
}
if ($acm) {
eval {
cp_af(glob_("$p/consoletrans/$acm*"), "$prefix/etc/sysconfig/console/consoletrans");
add2hash $h, { SYSFONTACM => $acm };
};
$@ and log::l("missing console acm file $acm");
}
}
add2hash $h, $xim{$h->{LANG}};
#- deactivate translations on console for RTL languages
if ($h->{LANG} =~ /ar|fa|he|ur|yi/) {
add2hash $h, { CONSOLE_NOT_LOCALIZED => 'yes' }
}
setVarsInSh($prefix . ($b_user_only ? "$ENV{HOME}/.i18n" : '/etc/sysconfig/i18n'), $h);
eval {
my $confdir = $prefix . ($b_user_only ? "$ENV{HOME}/.kde" : '/usr') . '/share/config';
-d $confdir or die 'not configuring kde config files since it is not installed/used';
configure_kdeglobals($locale, $confdir);
my %qt_xim = (zh => 'Over The Spot', ko => 'On The Spot', ja => 'On The Spot');
if ($b_user_only && (my $qt_xim = $qt_xim{substr($locale->{lang}, 0, 2)})) {
update_gnomekderc("$ENV{HOME}/.qt/qtrc", General => (XIMInputStyle => $qt_xim));
}
if (!$b_user_only && $locale->{lang} !~ /^(zh_TW|th|vi|be|bg)/) { #- skip since we don't have the right font (it badly fails at least for zh_TW)
my $kde_charset = charset2kde_charset(l2charset($locale->{lang}));
my $welcome = c::to_utf8(N("Welcome to %s", '%n'));
substInFile {
s/^(GreetString)=.*/$1=$welcome/;
s/^(Language)=.*/$1=$locale->{lang}/;
if (!member($kde_charset, 'iso8859-1', 'iso8859-15')) {
#- don't keep the default for those
s/^(StdFont)=.*/$1=*,12,5,$kde_charset,50,0/;
s/^(FailFont)=.*/$1=*,12,5,$kde_charset,75,0/;
s/^(GreetFont)=.*/$1=*,24,5,$kde_charset,50,0/;
}
} "$::prefix/usr/share/config/kdm/kdmrc";
}
} if !$b_dont_touch_kde_files;
}
sub configure_kdeglobals {
my ($locale, $confdir) = @_;
my $kdeglobals = "$confdir/kdeglobals";
my $charset = l2charset($locale->{lang});
my $kde_charset = charset2kde_charset($charset);
my ($prev_kde_charset) = cat_($kdeglobals) =~ /^Charset=(.*)/mi;
mkdir_p($confdir);
update_gnomekderc($kdeglobals, Locale => (
Charset => $kde_charset,
Country => lc($locale->{country}),
Language => get_kde_lang($locale),
));
if ($prev_kde_charset ne $kde_charset) {
update_gnomekderc($kdeglobals, WM => (
activeFont => charset2kde_font($charset,0),
));
update_gnomekderc($kdeglobals, General => (
fixed => charset2kde_font($charset, 1),
font => charset2kde_font($charset, 0),
menuFont => charset2kde_font($charset, 3),
taskbarFont => charset2kde_font($charset, 4),
toolBarFont => charset2kde_font($charset, 2),
));
update_gnomekderc("$confdir/konquerorrc", FMSettings => (
StandardFont => charset2kde_font($charset, 0),
));
update_gnomekderc("$confdir/kdesktoprc", FMSettings => (
StandardFont => charset2kde_font($charset, 0),
));
}
}
sub bindtextdomain() {
#- if $::prefix is set, search for libDrakX.mo in locale_special
#- NB: not using $::isInstall to make it work more easily at install and standalone
my $localedir = "$ENV{SHARE_PATH}/locale" . ($::prefix ? "_special" : '');
c::setlocale();
c::bind_textdomain_codeset('libDrakX', 'UTF-8');
$::need_utf8_i18n = 1;
c::bindtextdomain('libDrakX', $localedir);
$localedir;
}
sub load_mo {
my ($lang) = @_;
my $localedir = bindtextdomain();
my $suffix = 'LC_MESSAGES/libDrakX.mo';
$lang ||= $ENV{LANGUAGE} || $ENV{LC_ALL} || $ENV{LC_MESSAGES} || $ENV{LANG};
foreach (split ':', $lang) {
my $f = "$localedir/$_/$suffix";
-s $f and return $_;
if ($::isInstall && common::usingRamdisk()) {
#- cleanup
eval { rm_rf($localedir) };
eval { mkdir_p(dirname("$localedir/$_/$suffix")) };
install_any::getAndSaveFile("$localedir/$_/$suffix");
-s $f and return $_;
}
}
'';
}
#- used in Makefile during "make get_needed_files"
sub console_font_files() {
map { -e $_ ? $_ : "$_.gz" }
(map { "/usr/lib/kbd/consolefonts/$_.psf" } uniq grep { $_ } map { $_->[0] } values %charsets),
(map { -e $_ ? $_ : "$_.sfm" } map { "/usr/lib/kbd/consoletrans/$_" } uniq grep { $_ } map { $_->[1] } values %charsets),
(map { -e $_ ? $_ : "$_.acm" } map { "/usr/lib/kbd/consoletrans/$_" } uniq grep { $_ } map { $_->[2] } values %charsets),
}
sub load_console_font {
my ($locale) = @_;
my ($name, $sfm, $acm) = l2console_font($locale, 1);
require run_program;
run_program::run(if_($ENV{LD_LOADER}, $ENV{LD_LOADER}),
'consolechars', '-v', '-f', $name || 'lat0-sun16',
if_($sfm, '-u', $sfm), if_($acm, '-m', $acm));
#- in console mode install, ensure we'll get translations in the right codeset
#- (charset of locales reported by the glibc are UTF-8 during install)
if ($acm) {
c::bind_textdomain_codeset('libDrakX', l2charset($locale->{lang}));
$::need_utf8_i18n = 0;
}
}
sub fs_options {
my ($locale) = @_;
if ($locale->{utf8}) {
(iocharset => 'utf8', codepage => undef);
} else {
my $c = $charsets{l2charset($locale->{lang}) || return} or return;
my ($iocharset, $codepage) = @$c[3..4];
(iocharset => $iocharset, codepage => $codepage);
}
}
sub during_install__l2charset {
my ($lang) = @_;
return if member($lang, @during_install__lang_having_their_LC_CTYPE);
my ($c) = l2charset($lang) or die "bad lang $lang\n";
$c = 'UTF-8' if member($c, 'tis620', 'C', 'unicode');
$c = 'UTF-8' if $c =~ /koi8-/;
$c = 'UTF-8' if $c =~ /iso-8859/;
$c = 'UTF-8' if $c =~ /cp125/;
$c = 'UTF-8' if $c =~ /utf_/;
uc($c);
}
sub get_unneeded_png_lang_files() {
print join(' ', map { if_(m|(langs/lang-(.*)\.png)| && !member($2, list_langs()), $1) } glob("pixmaps/langs/lang-*.png"));
}
sub check() {
$^W = 0;
my $ok = 1;
my $warn = sub {
print STDERR "$_[0]\n";
};
my $err = sub {
&$warn;
$ok = 0;
};
my @wanted_charsets = uniq map { l2charset($_) } list_langs();
print "\tWarnings:\n";
$warn->("unused charset $_ (given in \%charsets, but not used in \%langs)") foreach difference2([ keys %charsets ], \@wanted_charsets);
$warn->("unused entry $_ in \%xim") foreach grep { !/UTF-8/ } difference2([ keys %xim ], [ map { l2locale($_) } list_langs() ]);
#- consolefonts are checked during build via console_font_files()
if (my @l = difference2([ 'default', keys %charsets ], [ keys %charset2kde_font ])) {
$warn->("no kde font for charset " . join(" ", @l));
}
if (my @l = grep { get_kde_lang({ lang => $_, country => 'US' }, 'err') eq 'err' } list_langs()) {
$warn->("no KDE lang for langs " . join(" ", @l));
}
if (my @l = grep { charset2kde_charset($_, 'err') eq 'err' } keys %charsets) {
$warn->("no KDE charset for charsets " . join(" ", @l));
}
$warn->("no country corresponding to default locale $_->[1] of lang $_->[0]")
foreach grep { $_->[1] =~ /^.._(..)/ && !exists $countries{$1} } map { [ $_, l2locale($_) ] } list_langs();
print "\tErrors:\n";
$err->("invalid charset $_ ($_ does not exist in \%charsets)") foreach difference2(\@wanted_charsets, [ keys %charsets ]);
$err->("invalid charset $_ in \%charset2kde_font ($_ does not exist in \%charsets)") foreach difference2([ keys %charset2kde_font ], [ 'default', keys %charsets ]);
$err->("default locale $_->[1] of lang $_->[0] isn't listed in \@locales")
foreach grep { !member($_->[1], @locales) } map { [ $_, l2locale($_) ] } list_langs();
$err->("lang image for lang $_->[0] is missing (file $_->[1])")
foreach grep { !(-e $_->[1]) } map { [ $_, "pixmaps/langs/lang-$_.png" ] } list_langs();
$err->("default locale $_->[1] of country $_->[0] isn't listed in \@locales")
foreach grep { !member($_->[1], @locales) } map { [ $_, c2locale($_) ] } list_countries();
exit($ok ? 0 : 1);
}
1;