blob: 5e8356350fc8b2807c7fb6b4666d4b37a8c69b7e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
#include "dietfeatures.h"
.text
.global _start
_start:
#ifdef WANT_DYNAMIC
movq %rdx, %rcx /* %rcx = dynamic fini */
#endif
popq %rdi /* %rdi = argc */
movq %rsp,%rsi /* %rsi = argv */
pushq %rdi
leaq 8(%rsi,%rdi,8),%rdx /* %rdx = envp = (8*rdi)+%rsi+8 */
#ifdef __DYN_LIB
movq environ@GOTPCREL(%rip), %rax
movq %rdx, (%rax)
#else
movq %rdx, environ(%rip)
#endif
#ifdef PROFILING
pushq %rdi /* save reg args */
pushq %rsi
pushq %rdx
pushq %rcx
leaq _etext(%rip), %rsi /* highpc */
leaq .text(%rip), %rdi /* lowpc */
call monitor
popq %rcx /* restore reg args */
popq %rdx
popq %rsi
popq %rdi
#endif
#ifdef WANT_DYNAMIC
call _dyn_start
#else
call main
#endif
#ifdef PROFILING
pushq %rax
call _stop_monitor
popq %rdi
#else
movq %rax, %rdi /* return value */
#endif
call exit
hlt
.Lstart:
.size _start,.Lstart-_start
|