package interactive; # $Id$
use diagnostics;
use strict;
#-######################################################################################
#- misc imports
#-######################################################################################
use common;
use do_pkgs;
#- minimal example using interactive:
#
#- > use lib qw(/usr/lib/libDrakX);
#- > use interactive;
#- > my $in = interactive->vnew;
#- > $in->ask_okcancel('title', 'question');
#- > $in->exit;
#- ask_from_ takes global options ($common):
#- title => window title
#- messages => message displayed in the upper part of the window
#- advanced_messages => message displayed when "Advanced" is pressed
#- ok => force the name of the "Ok"/"Next" button
#- cancel => force the name of the "Cancel"/"Previous" button
#- advanced_label => force the name of the "Advanced" button
#- advanced_label_close => force the name of the "Basic" button
#- advanced_state => if set to 1, force the "Advanced" part of the dialog to be opened initially
#- focus_cancel => force focus on the "Cancel" button
#- focus_first => force focus on the first entry
#- callbacks => functions called when something happen: complete canceled advanced changed focus_out ok_disabled
#- ask_from_ takes a list of entries with fields:
#- val => reference to the value
#- label => description
#- icon => icon to put before the description
#- help => tooltip
#- advanced => wether it is shown in by default or only in advanced mode
#- disabled => function returning wether it should be disabled (grayed)
#- gtk => gtk preferences
#- type =>
#- button => (with clicked or clicked_may_quit)
#- (type defaults to button if clicked or clicked_may_quit is there)
#- (val need not be a reference) (if clicked_may_quit return true, it's as if "Ok" was pressed)
#- label => (val need not be a reference) (type defaults to label if val is not a reference)
#- bool (with "text" or "image" (which overrides text) giving an image filename)
#- range (with min, max)
#- combo (with list, not_edit, format)
#- list (with list, icon2f (aka icon), separator (aka tree), format (aka pre_format function),
#- help can be a hash or a function,
#- tree_expanded boolean telling wether the tree should be wide open by default
#- quit_if_double_click boolean
#- allow_empty_list disables the special cases for 0 and 1 element lists
#- image2f is a subroutine which takes a value of the list as parameter, and returns an array (text, image_file_name))
#- entry (the default) (with hidden)
#
#- heritate from this class and you'll get all made interactivity for same steps.
#- for this you need to provide
#- - ask_from_listW(o, title, messages, arrayref, default) returns one string of arrayref
#-
#- where
#- - o is the object
#- - title is a string
#- - messages is an refarray of strings
#- - default is an optional string (default is in arrayref)
#- - arrayref is an arrayref of strings
#- - arrayref2 contains booleans telling the default state,
#-
#- ask_from_list and ask_from_list_ are wrappers around ask_from_biglist and ask_from_smalllist
#-
#- ask_from_list_ just translate arrayref before calling ask_from_list and untranslate the result
#-
#- ask_from_listW should handle differently small lists and big ones.
#-
#-######################################################################################
#- OO Stuff
#-######################################################################################
our @ISA = qw(do_pkgs);
sub new($) {
my ($type) = @_;
bless {}, ref($type) || $type;
}
sub vnew {
my ($_type, $o_su, $o_icon) = @_;
my $su = $o_su eq "su";
if ($ENV{INTERACTIVE_HTTP}) {
require interactive::http;
return interactive::http->new;
}
require c;
if ($su) {
$ENV{PATH} = "/sbin:/usr/sbin:$ENV{PATH}";
$su = '' if $::testing || $ENV{TESTING};
}
require_root_capability() if $su;
if (check_for_xserver()) {
eval { require interactive::gtk };
if (!$@) {
my $o = interactive::gtk->new;
if ($o_icon && $o_icon ne 'default' && !$::isWizard) { $o->{icon} = $o_icon } else { undef $o->{icon} }
return $o;
} elsif ($::testing) {
die;
}
}
require 'log.pm'; #- "require log" causes some pb, perl thinking that "log" is the log() function
undef *log::l;
*log::l = sub {}; # otherwise, it will bother us :(
require interactive::newt;
interactive::newt->new;
}
sub enter_console {}
sub leave_console {}
sub suspend {}
sub resume {}
sub end {}
sub exit {
if ($::isStandalone) {
require standalone;
standalone::exit($_[0]);
} else {
exit($_[0]);
}
}
#-######################################################################################
#- Interactive functions
#-######################################################################################
sub ask_warn {
my ($o, $title, $message) = @_;
ask_warn_($o, { title => $title, messages => $message });
}
sub ask_yesorno {
my ($o, $title, $message, $b_def) = @_;
ask_yesorno_($o, { title => $title, messages => $message }, $b_def);
}
sub ask_okcancel {
my ($o, $title, $message, $b_def) = @_;
ask_okcancel_($o, { title => $title, messages => $message }, $b_def);
}
sub ask_warn_ {
my ($o, $common) = @_;
ask_from_listf_raw_no_check($o, $common, undef, [ $o->ok ]);
}
sub ask_yesorno_ {
my ($o, $common, $b_def) = @_;
$common->{cancel} = '';
ask_from_listf_raw($o, $common, sub { translate($_[0]) }, [ N_("Yes"), N_("No") ], $b_def ? "Yes" : "No") eq "Yes";
}
sub ask_okcancel_ {
my ($o, $common, $b_def) = @_;
if ($::isWizard) {
$::no_separator = 1;
$common->{focus_cancel} = !$b_def;
ask_from_no_check($o, $common, []);
} else {
ask_from_listf_raw($o, $common, sub { translate($_[0]) }, [ $o->ok, $o->cancel ], $b_def ? $o->ok : "Cancel") eq $o->ok;
}
}
sub ask_filename {
my ($o, $common) = @_;
$common->{want_a_dir} = 0;
$o->ask_fileW($common);
}
sub ask_directory {
my ($o, $common) = @_;
$common->{want_a_dir} = 1;
$o->ask_fileW($common);
}
#- predecated
sub ask_file {
my ($o, $title, $o_dir) = @_;
$o->ask_fileW({ title => $title, want_a_dir => 0, directory => $o_dir });
}
sub ask_fileW {
my ($o, $common) = @_;
$o->ask_from_entry($common->{title}, $common->{message} || N("Choose a file"));
}
sub ask_from_list {
my ($o, $title, $message, $l, $o_def) = @_;
ask_from_listf($o, $title, $message, undef, $l, $o_def);
}
sub ask_from_list_ {
my ($o, $title, $message, $l, $o_def) = @_;
ask_from_listf($o, $title, $message, sub { translate($_[0]) }, $l, $o_def);
}
sub ask_from_listf_ {
my ($o, $title, $message, $f, $l, $o_def) = @_;
ask_from_listf($o, $title, $message, sub { translate($f->(@_)) }, $l, $o_def);
}
sub ask_from_listf {
my ($o, $title, $message, $f, $l, $o_def) = @_;
ask_from_listf_raw($o, { title => $title, messages => $message }, $f, $l, $o_def);
}
sub ask_from_listf_raw {
my ($_o, $_common, $_f, $l, $_o_def) = @_;
@$l == 0 and die "ask_from_list: empty list\n" . backtrace();
@$l == 1 and return $l->[0];
goto &ask_from_listf_raw_no_check;
}
sub ask_from_listf_raw_no_check {
my ($o, $common, $f, $l, $o_def) = @_;
if (@$l <= ($::isWizard ? 1 : 2)) {
my ($ok, $cancel) = map { $_ && may_apply($f, $_) } @$l;
if (length "$ok$cancel" < 70) {
my $ret = eval {
put_in_hash($common, { ok => $ok,
if_($cancel, cancel => $cancel, focus_cancel => $o_def eq $l->[1]) });
ask_from_no_check($o, $common, []) ? $l->[0] : $l->[1];
};
die if $@ && $@ !~ /^wizcancel/;
return $@ ? undef : $ret;
}
}
ask_from_no_check($o, $common, [ { val => \$o_def, type => 'list', list => $l, format => $f } ]) && $o_def;
}
sub ask_from_treelist {
my ($o, $title, $message, $separator, $l, $o_def) = @_;
ask_from_treelistf($o, $title, $message, $separator, undef, $l, $o_def);
}
sub ask_from_treelist_ {
my ($o, $title, $message, $separator, $l, $o_def) = @_;
my $transl = sub { join '|', map { translate($_) } split(quotemeta($separator), $_[0]) };
ask_from_treelistf($o, $title, $message, $separator, $transl, $l, $o_def);
}
sub ask_from_treelistf {
my ($o, $title, $message, $separator, $f, $l, $o_def) = @_;
ask_from($o, $title, $message, [ { val => \$o_def, separator => $separator, list => $l, format => $f, sort => 1 } ]) or return;
$o_def;
}
sub ask_many_from_list {
my ($o, $title, $message, @l) = @_;
@l = grep { @{$_->{list}} } @l or return '';
foreach my $h (@l) {
$h->{e}{$_} = {
text => may_apply($h->{label}, $_),
val => $h->{val} ? $h->{val}->($_) : do {
my $i =
$h->{value} ? $h->{value}->($_) :
$h->{values} ? member($_, @{$h->{values}}) : 0;
\$i;
},
type => 'bool',
help => may_apply($h->{help}, $_, ''),
icon => may_apply($h->{icon2f}, $_, ''),
} foreach @{$h->{list}};
if ($h->{sort}) {
$h->{list} = [ sort { $h->{e}{$a}{text} cmp $h->{e}{$b}{text} } @{$h->{list}} ];
}
}
$o->ask_from($title, $message, [ map { my $h = $_; map { $h->{e}{$_} } @{$h->{list}} } @l ]) or return;
@l = map {
my $h = $_;
[ grep { ${$h->{e}{$_}{val}} } @{$h->{list}} ];
} @l;
wantarray() ? @l : $l[0];
}
sub ask_from_entry {
my ($o, $title, $message, %callback) = @_;
first(ask_from_entries($o, $title, $message, [''], %callback));
}
sub ask_from_entries {
my ($o, $title, $message, $l, %callback) = @_;
my @l = map { my $i = ''; { label => $_, val => \$i } } @$l;
$o->ask_from_({ title => $title, messages => $message, callbacks => \%callback,
focus_first => 1 }, \@l) or return;
map { ${$_->{val}} } @l;
}
sub ask_from__add_modify_remove {
my ($o, $title, $message, $l, %callback) = @_;
die "ask_from__add_modify_remove only handles one item" if @$l != 1;
$callback{$_} or internal_error("missing callback $_") foreach qw(Add Modify Remove);
if ($o->can('ask_from__add_modify_removeW')) {
$o->ask_from__add_modify_removeW($title, $message, $l, %callback);
} else {
my $e = $l->[0];
my $chosen_element;
put_in_hash($e, { allow_empty_list => 1, val => \$chosen_element, type => 'list' });
while (1) {
my $continue;
my @l = (@$l,
map { my $s = $_; { val => translate($_), clicked_may_quit => sub {
my $r = $callback{$s}->($chosen_element);
defined $r or return;
$continue = 1;
} } }
N_("Add"), if_(@{$e->{list}} > 0, N_("Modify"), N_("Remove")));
$o->ask_from_({ title => $title, messages => $message, callbacks => \%callback }, \@l) or return;
return 1 if !$continue;
}
}
}
#- can get a hash of callback: focus_out changed and complete
#- moreove if you pass a hash with a field list -> combo
#- if you pass a hash with a field hidden -> emulate stty -echo
sub ask_from {
my ($o, $title, $message, $l, %callback) = @_;
ask_from_($o, { title => $title, messages => $message, callbacks => \%callback }, $l);
}
sub ask_from_normalize {
my ($o, $common, $l) = @_;
ref($l) eq 'ARRAY' or internal_error('ask_from_normalize');
foreach my $e (@$l) {
if (my $li = $e->{list}) {
ref($e->{val}) =~ /SCALAR|REF/ or internal_error($e->{val} ? "field {val} must be a reference (it is $e->{val})" : "field {val} is mandatory"); #-#
if ($e->{sort} || @$li > 10 && !exists $e->{sort}) {
my @l2 = map { may_apply($e->{format}, $_) } @$li;
my @places = sort { $l2[$a] cmp $l2[$b] } 0 .. $#l2;
$e->{list} = $li = [ map { $li->[$_] } @places ];
}
$e->{type} = 'iconlist' if $e->{icon2f};
$e->{type} = 'treelist' if $e->{separator} && $e->{type} ne 'combo';
add2hash_($e, { not_edit => 1 });
$e->{type} ||= 'combo';
if (!$e->{not_edit}) {
die q(when using "not_edit" you must use strings, not a data structure) if ref(${$e->{val}}) || any { ref $_ } @$li;
}
if ($e->{type} ne 'combo' || $e->{not_edit}) {
${$e->{val}} = $li->[0] if !member(may_apply($e->{format}, ${$e->{val}}), map { may_apply($e->{format}, $_) } @$li);
}
} elsif ($e->{type} eq 'range') {
$e->{min} <= $e->{max} or die "bad range min $e->{min} > max $e->{max} (called from " . join(':', caller()) . ")";
${$e->{val}} = max($e->{min}, min(${$e->{val}}, $e->{max}));
} elsif ($e->{type} eq 'button' || $e->{clicked} || $e->{clicked_may_quit}) {
$e->{type} = 'button';
$e->{clicked_may_quit} ||= $e->{clicked} ? sub { $e->{clicked}(); 0 } : sub {};
$e->{val} = \ (my $_v = $e->{val}) if !ref($e->{val});
} elsif ($e->{type} eq 'label' || !ref($e->{val})) {
$e->{type} = 'label';
$e->{val} = \ (my $_v = $e->{val}) if !ref($e->{val});
} else {
$e->{type} ||= 'entry';
}
$e->{disabled} ||= sub { 0 };
}
#- do not display empty lists and one element lists
@$l = grep {
if ($_->{list} && $_->{not_edit} && !$_->{allow_empty_list}) {
if (!@{$_->{list}}) {
eval {
require 'log.pm'; #- "require log" causes some pb, perl thinking that "log" is the log() function
log::l("ask_from_normalize: empty list for $_->{label}\n" . backtrace());
};
}
@{$_->{list}} > 1;
} else {
1;
}
} @$l;
if (!$common->{title} && $::isStandalone) {
($common->{title} = $0) =~ s|.*/||;
}
$common->{interactive_help} ||= $o->{interactive_help};
$common->{interactive_help} ||= $common->{interactive_help_id} && $o->interactive_help_sub_get_id($common->{interactive_help_id});
$common->{advanced_label} ||= N("Advanced");
$common->{advanced_label_close} ||= N("Basic");
$common->{$_} = $common->{$_} ? [ deref($common->{$_}) ] : [] foreach qw(messages advanced_messages);
add2hash_($common->{callbacks} ||= {}, { changed => sub {}, focus_out => sub {}, complete => sub { 0 }, canceled => sub { 0 }, advanced => sub {} });
}
sub ask_from_ {
my ($o, $common, $l) = @_;
ask_from_normalize($o, $common, $l);
@$l or return 1;
$common->{cancel} = '' if !defined wantarray();
ask_from_real($o, $common, $l);
}
sub ask_from_no_check {
my ($o, $common, $l) = @_;
ask_from_normalize($o, $common, $l);
$common->{cancel} = '' if !defined wantarray();
my ($l1, $l2) = partition { !$_->{advanced} } @$l;
$o->ask_fromW($common, $l1, $l2);
}
sub ask_from_real {
my ($o, $common, $l) = @_;
my ($l1, $l2) = partition { !$_->{advanced} } @$l;
my $v = $o->ask_fromW($common, $l1, $l2);
foreach my $e (@$l1, @$l2) {
if ($e->{type} eq 'range') {
${$e->{val}} = max($e->{min}, min(${$e->{val}}, $e->{max}));
}
}
%$common = ();
$v;
}
sub ask_browse_tree_info {
my ($o, $title, $message, $common) = @_;
$common->{interactive_help} ||= $common->{interactive_help_id} && $o->interactive_help_sub_get_id($common->{interactive_help_id});
add2hash_($common, { ok => $::isWizard ? ($::Wizard_finished ? N("Finish") : N("Next")) : N("Ok"),
cancel => $::isWizard ? N("Previous") : N("Cancel") });
add2hash_($common, { title => $title, message => $message });
add2hash_($common, { grep_allowed_to_toggle => sub { @_ },
grep_unselected => sub { grep { $common->{node_state}($_) eq 'unselected' } @_ },
check_interactive_to_toggle => sub { 1 },
toggle_nodes => sub {
my ($set_state, @nodes) = @_;
my $new_state = !$common->{grep_unselected}($nodes[0]) ? 'selected' : 'unselected';
$set_state->($_, $new_state) foreach @nodes;
},
});
$o->ask_browse_tree_info_refW($common);
}
sub ask_browse_tree_info_refW { #- default definition, do not use with too many items (memory consuming)
my ($o, $common) = @_;
my ($l, $v, $h) = ([], [], {});
$common->{build_tree}(sub {
my ($node) = $common->{grep_allowed_to_toggle}(@_);
if (my $state = $node && $common->{node_state}($node)) {
push @$l, $node;
$state eq 'selected' and push @$v, $node;
$h->{$node} = $state eq 'selected';
}
}, 'flat');
add2hash_($common, { list => $l, #- TODO interactivity of toggle is missing
values => $v,
help => sub { $common->{get_info}($_[0]) },
});
my ($new_v) = $o->ask_many_from_list($common->{title}, $common->{message}, $common) or return;
$common->{toggle_nodes}(sub {}, grep { ! delete $h->{$_} } @$new_v);
$common->{toggle_nodes}(sub {}, grep { $h->{$_} } keys %$h);
1;
}
sub wait_message {
my ($o, $title, $message, $b_temp) = @_;
my $w = $o->wait_messageW($title, [ N("Please wait"), deref($message) ]);
push @tempory::objects, $w if $b_temp;
my $b = before_leaving { $o->wait_message_endW($w) };
#- enable access through set
MDK::Common::Func::add_f4before_leaving(sub { $o->wait_message_nextW([ deref($_[1]) ], $w) }, $b, 'set');
$b;
}
sub kill() {}
sub helper_separator_tree_to_tree {
my ($separator, $list, $formatted_list) = @_;
my $sep = quotemeta $separator;
my $tree = {};
each_index {
my @l = split $sep;
my $leaf = pop @l;
my $node = $tree;
foreach (@l) {
$node = $node->{$_} ||= do {
my $r = {};
push @{$node->{_order_}}, $_;
$r;
};
}
push @{$node->{_leaves_}}, [ $leaf, $list->[$::i] ];
();
} @$formatted_list;
$tree;
}
sub interactive_help_has_id {
my ($_o, $id) = @_;
exists $help::{$id};
}
sub interactive_help_get_id {
my ($_o, @l) = @_;
@l = map {
join("\n\n", map { s/\n/ /mg; $_ } split("\n\n", translate($help::{$_}->())));
} grep { exists $help::{$_} } @l;
join("\n\n\n", @l);
}
sub interactive_help_sub_get_id {
my ($o, $id) = @_;
$o->interactive_help_has_id($id) && sub { $o->interactive_help_get_id($id) };
}
sub interactive_help_sub_display_id {
my ($o, $id) = @_;
$o->interactive_help_has_id($id) && sub { $o->ask_warn(N("Help"), $o->interactive_help_get_id($id)) };
}
1;
'n359' href='#n359'>359
360
361
362
363
364
365
366
367
368
369
370
package install2;
use diagnostics;
use strict;
use vars qw($o);
use common qw(:common :file :system);
use install_any qw(:all);
use log;
use network;
use keyboard;
use fs;
use fsedit;
use install_steps_graphical;
use modules;
use partition_table qw(:types);
use detect_devices;
use pkgs;
use smp;
use lang;
use run_program;
my %stepsHelp = (
selectLanguage =>
__("Choose the language which you approved. This one govern the language's system."),
selectPath =>
__("Choose \"Installation\" if you never have installed Linux system on this computer or if you wish
to install several of them on this machine.
Choose \"Update\" if you wish to update a Linux system Mandrake 5.1 (Venice), 5.2 (Leeloo), 5.3 (Festen) or
6.0 (Venus)."),
selectInstallClass =>
__("Select:
- Beginer: if you have never installed Linux system and wish to install the system elected
\"Product of the year\" for 1999, click here.
- Developer: if wish to use your Linux system to build software, you will find your happiness here.
- Server: if you wish to install the operating system elected \"Distribution/Server\" for 1999,
choose this installation class.
- Expert: if you alway know very fine GNU/Linux and that you wish to preserve the whole
control of the installation, this class is for you."),
setupSCSI =>
__("The system did not detect a SCSI card. If you have one (or several) click on \"Yes\" and choose the module
to be tested. In the contrary case, cliquez on \"Not\".
If you don't know if you have interfaces SCSI, consult the documentation delivered with your computer
or, if you use Microsoft Windows 95/98, consult the file \"Peripheral manager\" of the item \"System\"
of the \"Control panel\"."),
partitionDisks =>
__("In this stage, you will must partion your hard disk. It consists in cutting your disk in several zones
(which are not equal). This operation, for spectacular and intimidating that it is,
is not hardly if you be carrefull so that you do.
Also, take your time, are sure you before click on \"Finishing\" and READ the handbook of DiskDrake
before use them."),
formatPartitions =>
__("The partitions lately created must be formatted so that the system can use them.
You can also format partitions before created and used if you wish to remove all the data which
contain. Note that it is not necessary to format the partitions created before used if they contain data to
which you want to keep (typical cases: / home and / usr/local)."),
choosePackages =>
__("You now have the possibility of choosing the software which you wish to install.
Please note that packages manage the dependences: that means that if you wish to install
a software requiring the presence of another software, this last will be automatically selected
and that it will be impossible for you to install the first without installing the second.
Information on each category of packages and each one of enter of them are available in zone \"Infos\"
located above buttons of confirmation/selection/deselection."),
doInstallStep =>
__("Selected packages are now getting installed on your system. This operation take only a few minutes."),
setRootPassword =>
__("The system now requires an administrator password for your Linux system.
This passwd is required of you by twice in order to being certain of its spelling.
Choose it carefully because it mainly conditions the good functioning of your system.
Indeed, only the administrator (also named \"root\") is able to configure the computer.
The password should not be too simple so that whoever cannot be connected under this account.
It should not be either too sophisticated under penalty of being difficult to retain and, finally, forgotten.
When you wish to connect yourselves on your Linux system as an administrator, the \"login\"
is \"root\" and the \"passswrd\", this one which you now will indicate."),
addUser =>
__("You can now authorize one or more people to be connected on your Linux system. Each one of
them will profit from his own environment will be able to configure.
It is very important that you create at least one user even if you are the only person who will connect
herself on this machine. Indeed, if runnig the system as \"root\" is attractive, that
is a very bad idea. This last having all the rights it is certain that at one time you will broke all.
This is highly preferable you connect as simple user and that you use the account \"root\" only when
that is essential."),
doInstallStep =>
__("The system being now copied on your disk, he is now time to indicate to him from where he will have to start.
With less than you know exactly what you do, always choose \"First sector of drive\"."),
configureX =>
__("It is now time to configure the graphic server. First of all, choose your monitor. You have then
the possibility of testing your configuration and of reconsidering your choices if the latter are not
appropriate to you."),
);
my @installStepsFields = qw(text redoable onError needs);
my @installSteps = (
selectLanguage => [ __("Choose your language"), 1, 1 ],
selectPath => [ __("Choose install or upgrade"), 0, 0 ],
selectInstallClass => [ __("Select installation class"), 1, 1, "selectPath" ],
setupSCSI => [ __("Setup SCSI"), 1, 0 ],
partitionDisks => [ __("Setup filesystems"), 1, 0 ],
formatPartitions => [ __("Format partitions"), 1, -1, "partitionDisks" ],
choosePackages => [ __("Choose packages to install"), 1, 1, "selectInstallClass" ],
doInstallStep => [ __("Install system"), 1, -1, ["formatPartitions", "selectPath"] ],
# configureMouse => [ __("Configure mouse"), 0, 0 ],
configureNetwork => [ __("Configure networking"), 1, 1, "formatPartitions" ],
# configureTimezone => [ __("Configure timezone"), 0, 0 ],
# configureServices => [ __("Configure services"), 0, 0 ],
# configurePrinter => [ __("Configure printer"), 0, 0 ],
setRootPassword => [ __("Set root password"), 1, 0, "formatPartitions" ],
addUser => [ __("Add a user"), 1, 0, "formatPartitions" ],
createBootdisk => [ __("Create bootdisk"), 1, 0, "doInstallStep" ],
setupBootloader => [ __("Install bootloader"), 1, 1, "doInstallStep" ],
configureX => [ __("Configure X"), 1, 0, "doInstallStep" ],
exitInstall => [ __("Exit install"), 0, 0, "alldone" ],
);
my (%installSteps, %upgradeSteps, @orderedInstallSteps, @orderedUpgradeSteps);
for (my $i = 0; $i < @installSteps; $i += 2) {
my %h; @h{@installStepsFields} = @{ $installSteps[$i + 1] };
$h{help} = $stepsHelp{$installSteps[$i]} || __("Help");
$h{next} = $installSteps[$i + 2];
$h{onError} = $installSteps[$i + 2 * $h{onError}];
$installSteps{ $installSteps[$i] } = \%h;
push @orderedInstallSteps, $installSteps[$i];
}
$installSteps{first} = $installSteps[0];
my @install_classes = (__("beginner"), __("developer"), __("server"), __("expert"));
# partition layout for a server
my @serverPartitioning = (
{ mntpoint => "/boot", size => 16 << 11, type => 0x83 },
{ mntpoint => "/", size => 256 << 11, type => 0x83 },
{ mntpoint => "/usr", size => 512 << 11, type => 0x83, growable => 1 },
{ mntpoint => "/var", size => 256 << 11, type => 0x83 },
{ mntpoint => "/home", size => 512 << 11, type => 0x83, growable => 1 },
{ mntpoint => "swap", size => 64 << 11, type => 0x82 }
);
my $default = {
lang => 'us',
isUpgrade => 0,
installClass => 'beginner',
# display => "192.168.1.9:0",
bootloader => { onmbr => 1, linear => 0 },
autoSCSI => 0,
mkbootdisk => 0,
packages => [ qw() ],
partitionning => { clearall => $::testing, eraseBadPartitions => 1, auto_allocate => 0, autoformat => 1 },
partitions => [
{ mntpoint => "/boot", size => 16 << 11, type => 0x83 },
{ mntpoint => "/", size => 300 << 11, type => 0x83 },
{ mntpoint => "swap", size => 64 << 11, type => 0x82 },
# { mntpoint => "/usr", size => 400 << 11, type => 0x83, growable => 1 },
],
shells => [ map { "/bin/$_" } qw(bash tcsh zsh ash) ],
};
$o = $::o = {
# lang => 'fr',
# isUpgrade => 0,
# installClass => 'beginner',
default => $default,
steps => \%installSteps,
orderedSteps => \@orderedInstallSteps,
# for the list of fields available for user and superuser, see @etc_pass_fields in install_steps.pm
# user => { name => 'foo', password => 'bar', home => '/home/foo', shell => '/bin/bash', realname => 'really, it is foo' },
# superuser => { password => 'a', shell => '/bin/bash', realname => 'God' },
base => [ qw(basesystem initscripts console-tools mkbootdisk linuxconf anacron linux_logo rhs-hwdiag utempter ldconfig chkconfig ntsysv mktemp setup setuptool filesystem MAKEDEV SysVinit ash at authconfig bash bdflush binutils console-tools crontabs dev e2fsprogs ed etcskel file fileutils findutils getty_ps gpm grep groff gzip hdparm info initscripts isapnptools kbdconfig kernel less ldconfig lilo logrotate losetup man mkinitrd mingetty modutils mount net-tools passwd procmail procps psmisc mandrake-release rootfiles rpm sash sed setconsole setserial shadow-utils sh-utils slocate stat sysklogd tar termcap textutils time timeconfig tmpwatch util-linux vim-minimal vixie-cron which) ],
};
sub selectLanguage {
lang::set($o->{lang} = $o->chooseLanguage);
$o->{keyboard} = keyboard::setup();
addToBeDone {
unless ($o->{isUpgrade}) {
keyboard::write($o->{prefix}, $o->{keyboard});
lang::write($o->{prefix});
}
} 'doInstallStep';
}
sub selectPath {
$o->{isUpgrade} = $o->selectInstallOrUpgrade;
$o->{steps} = $o->{isUpgrade} ? \%upgradeSteps : \%installSteps;
$o->{orderedSteps} = $o->{isUpgrade} ? \@orderedUpgradeSteps : \@orderedInstallSteps;
}
sub selectInstallClass {
$o->{installClass} = $o->selectInstallClass(@install_classes);
$::expert = $o->{installClass} eq "expert";
}
sub setupSCSI {
$o->{autoSCSI} ||= $o->{installClass} eq "beginner";
$o->setupSCSI($o->{autoSCSI} && !$_[0]);
}
sub partitionDisks {
$o->{drives} = [ detect_devices::hds() ];
$o->{hds} = fsedit::hds($o->{drives}, $o->{default}{partitionning});
unless (@{$o->{hds}} > 0) {
$o->setupSCSI if $o->{autoSCSI}; # ask for an unautodetected scsi card
}
|