From 4cd6a4a5d7e49d54d53dcf4a6f3393d50bd88e8b Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Gwenol=C3=A9=20Beauchesne?= <gbeauchesne@mandriva.org>
Date: Wed, 4 Jun 2003 18:44:09 +0000
Subject: Import dietlibc 0.22 + other fixes for AMD64

---
 mdk-stage1/dietlibc/i386/mmap64.S | 63 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 mdk-stage1/dietlibc/i386/mmap64.S

(limited to 'mdk-stage1/dietlibc/i386/mmap64.S')

diff --git a/mdk-stage1/dietlibc/i386/mmap64.S b/mdk-stage1/dietlibc/i386/mmap64.S
new file mode 100644
index 000000000..421325260
--- /dev/null
+++ b/mdk-stage1/dietlibc/i386/mmap64.S
@@ -0,0 +1,63 @@
+#include <dietfeatures.h>
+#include <syscalls.h>
+#include <errno.h>
+
+#ifdef __DYN_LIB
+#ifndef WANT_THREAD_SAFE
+#define WANT_THREAD_SAFE
+#endif
+#endif
+
+.text
+.global mmap64
+.type mmap64,@function
+mmap64:
+/* man is this ugly! */
+  push	%ebp
+  push	%edi
+  push	%esi
+  push	%ebx
+  movl	%esp, %edi
+  movl	0x28(%edi), %eax
+  movl	0x2c(%edi), %edx
+  testl	$0xfff, %eax	/* offset in pages */
+  jnz	.Leinval
+  shrdl	$12, %edx, %eax
+  shrl	$12, %edx
+  jnz	.Leinval
+  movl	%eax, %ebp
+  movl	0x14(%edi),%ebx
+  movl	0x18(%edi),%ecx
+  movl	0x1c(%edi),%edx
+  movl	0x20(%edi),%esi
+  movl	0x24(%edi),%edi
+  movl	$__NR_mmap2,%eax
+  int	$0x80
+  cmp	$-124,%eax
+  jbe	.Lnoerror
+  neg	%eax
+.Lerror:
+#ifdef WANT_THREAD_SAFE
+  movl	%eax,%ebx
+#ifdef __DYN_LIB
+  call	__errno_location@PLT
+#else
+  call	__errno_location
+#endif
+  movl	%ebx,(%eax)
+  orl	$-1,%eax
+#else
+  mov	%eax,errno
+  sbb	%eax,%eax               # eax = eax - eax - CY = -1
+#endif
+.Lnoerror:
+  pop	%ebx
+  pop	%esi
+  pop	%edi
+  pop	%ebp
+  ret
+.Leinval:
+  movl $EINVAL,%eax
+  jmp .Lerror
+.Lende2:
+.size mmap64,.Lende2-mmap64
-- 
cgit v1.2.1