#!/usr/bin/perl

use lib qw(/usr/lib/libDrakX);
# i18n: IMPORTANT: to get correct namespace (transfugdrake instead of libDrakX)
BEGIN { unshift @::textdomains, 'transfugdrake' }
use strict;
use warnings;
use standalone;
use wizards;
use interactive;
use common;
use transfugdrake;

my %distrib = distrib();
my $windows_disk = transfugdrake::get_windows_disk();
my @linux_users = uniq(list_users());
my @windows_users;
@windows_users = transfugdrake::list_windows_users($windows_disk) if $windows_disk;

my @windows_items;
my $linux_user;
my $windows_user;
my $files_migration_type;
my $bookmarks_migration_type;
my $mail_migration_type;
my $background_migration_type;

my @step_items = (
    "files", [ "My Documents", "My Music", "My Pictures" ],
    "bookmarks", [ "Internet Explorer", "Mozilla Firefox" ],
    "mail", [ "Outlook Express" ],
    "background", [ "Wallpaper" ],
);
my @steps;

my $icon = 'migrationtools-52';
$ugtk2::wm_icon = $icon;

my $in = 'interactive'->vnew('su');
my $wiz = wizards->new({
    name => N("Migration wizard"),
    pages => {
        welcome => {
            name => N("This wizard will help you to import Windows documents and settings in your %s distribution.", $distrib{system}) . "\n" . N("It allows two different migration methods: you can either import all documents and settings by copying them in your home directory, or share them between operating systems."),
            post => sub {
                @windows_users or return 'no_windows';
                $linux_user = @linux_users == 1 && $linux_users[0];
                $windows_user = @windows_users == 1 && $windows_users[0];
                !$linux_user || !$windows_user ? 'users' : 'files';
            },
        },
        users => {
            name => N("Multiple users have been detected, please select a user in the list below."),
            data => [
                {
                    label => N("Windows user"),
                    type => 'combo',
                    val => \$windows_user,
                    list => \@windows_users,
                },
                {
                    label => N("Linux user"),
                    type => 'combo',
                    val => \$linux_user,
                    list => \@linux_users,
                },
            ],
            post => sub { first_step() },
        },
        files => {
            name => N("Migrate your Windows documents to your home directory. Documents can be imported by copying them, or they can be shared with the other operating system"),
            data => [
                {
                    type => 'list',
                    val => \$files_migration_type,
                    list => [
                        N("Import documents (recommended)"),
                        N("Share documents"),
                        N("Skip step"),
                    ],
                },
            ],
            post => sub {
                my $_w = $in->wait_message('', N("Migration of documents in progress"));
                step_import('files');
                next_step();
            },
        },
        bookmarks => {
            name => N("Migrate your browser bookmarks"),
            data => [
                {
                    type => 'list',
                    val => \$bookmarks_migration_type,
                    list => [
                        N("Import bookmarks (recommended)"),
                        if_(member('Mozilla Firefox', @windows_items),
                            N("Share bookmarks")),
                        N("Skip step"),
                    ],
                },
            ],
            post => sub {
                my $_w = $in->wait_message('', N("Migration of bookmarks in progress"));
                step_import('bookmarks');
                next_step();
            },
        },
        mail => {
            name => N("Migrate your mail settings"),
            data => [
                { type => 'list',
                  val => \$mail_migration_type,
                  list => [
                      N("Import mail (recommended)"),
                      if_(member('Mozilla Thunderbird', @windows_items),
                          N("Share mail")),
                      N("Skip step"),
                  ],
              },
            ],
            post => sub {
                my $_w = $in->wait_message('', N("Migration of mail in progress"));
                step_import('mail');
                next_step();
            },
        },
        background => {
            name => N("Migrate your desktop background"),
            data => [
                { type => 'list',
                  val => \$background_migration_type,
                  list => [
                      N("Use Mandriva background"),
                      N("Import background"),
                  ],
              },
            ],
            post => sub {
                my $_w = $in->wait_message('', N("Migration of background in progress"));
                step_import('background');
                next_step();
            },
        },
        end => {
            name => N("Congratulations, your migration is now complete!"),
            end => 1,
        },
        no_windows => {
            name => N("No Windows installation has been detected."),
            end => 1,
        },
        nothing => {
            name => N("No documents and settings have been detected."),
            end => 1,
        },
    },
});

$wiz->process($in);

sub first_step() {
    @windows_items = transfugdrake::list_windows_items($windows_disk, $windows_user);
    @steps = map { $_->[0] } grep { intersection(\@windows_items, $_->[1]) } group_by2(@step_items);
    @steps ? next_step() : 'nothing';
}

sub next_step() { shift(@steps) || 'end' }

sub step_import {
    my ($stepname) = @_;
    my $step = find { $_->[0] eq $stepname } group_by2(@step_items);
    my @targets = intersection(\@windows_items, $step->[1]);
    transfugdrake::import_target($windows_disk, $windows_user, $linux_user, $_) foreach @targets;
}