aboutsummaryrefslogtreecommitdiffstats
path: root/perl.req-from-meta
blob: a38244ae086e1928e194f775d1d8ade5e3df5b0f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
#!/usr/bin/perl

use strict;
use warnings;

use JSON qw{ from_json };
use YAML qw{ Load      };

# slurp the file
my $path = <>;
chomp($path);
open my $fh, '<', $path or die "can't open $path: $!";
my $data = do { local $/; <$fh> };
close $fh;

# parse meta - either yaml or json
my $meta = $path =~ /\.yml$/
    ? Load( $data )
    : from_json( $data );

# dump the requires with their version
my $requires = $meta->{"meta-spec"}{version} >= 2
    ? $meta->{prereqs}{runtime}{requires}
    : $meta->{requires};
foreach my $module ( sort keys %$requires ) {
    next if $module eq 'perl'; # minimum perl version
    my $version = $requires->{$module};
    if ( $version == 0 ) {
        print "perl($module)\n";
    } else {
        my $v = qx{ rpm --eval '%perl_convert_version $version' };
        print "perl($module) >= $v";
    }
}

exit;

=head1 NAME

perl.req-from-meta - extract requires from meta file

=head1 SYNOPSIS

    $ perl.req-from-meta /path/to/META.yml
    $ perl.req-from-meta /path/to/META.json

=head1 DESCRIPTION

This script will extract Perl requirements from the distribution meta
file. For each such requires, it'll convert the minimum version to
follow Mageia perl versioning (using C<%perl_convert_version>), and
print them as:

    perl(Foo::Bar)
    perl(App::Frobnizer) >= 1.23.456

Minimum perl version are skipped.