#!/usr/bin/perl

# $Id$

use strict;
use warnings;
use File::Find;
use Getopt::Long;
use Pod::Usage;

GetOptions(
    'all-name'   => \my $allname,
    'with-gnome' => \my $withgnome,
    'with-kde'   => \my $withkde,
    'with-html'  => \my $withhtml,
    'without-mo' => \my $withoutmo,
    'with-man' => \my $withman,
    'debug' =>  \my $debug,
) or pod2usage();

my ($buildroot, @searchname) = @ARGV;
$buildroot or die "No buildroot given\n";
$buildroot =~ s:/+$::; # removing trailing /
my ($pkgname) = @searchname or die "Main name to find missing\n";

sub debug {
    $debug or return;
    my ($msg, @val) = @_;
    printf("DEBUG: $msg\n", @val);
}

my %finallist; # filename => attr, easy way to perform uniq

File::Find::find(
    sub {
        my $file = substr($File::Find::name, length($buildroot));
        -f $File::Find::name or return;
        debug("next file is %s", $file);
        my ($pkg, $lang, $parent);
        if ($file =~ m:^((.*/share/locale)/([^/@]+)[^/]*).*/([^/]+)\.mo:) {
            if ($withoutmo) {
                return;
            }
            ($pkg, $lang, $parent) = ($4, $3, $2);
        } elsif ($file =~ m:^(.*/gnome/help)/([^/]+)/([^/]+).*$:) {
            if (!$withgnome) {
                return;
            }
            ($pkg, $lang, $parent) = ($2, $3, $1);
        } elsif ($file =~ m:^(.*/doc/kde)/HTML/([^/@]+)[^/]*/([^/]+)/.*$:) {
            if (!$withkde) {
                return;
            }
            ($pkg, $lang, $parent) = ($2, $3, $1);
        } elsif ($file =~ m:^(.*/doc)/HTML/([^/@]+)[^/]*/([^/_]+).*$:) {
            if (!$withhtml) {
                return;
            }
            ($pkg, $lang, $parent) = ($3, $2, $1);
        } elsif ($file =~ m:^(/+usr/share)/man/([^/@\.]+)[^/]*/man[^/]+/([^/.]+)\.\d[^/]*$:) {
            if (!$withman) {
                return;
            }
            ($pkg, $lang, $parent) = ($3, $2, $1);
            $file .= '*';
        } else {
            return;
        }
        if (! ((grep { $_ eq $pkg } @searchname) || $allname)) {
            return;
        }

        parent_to_own($parent, $file, $lang);
        $finallist{$file}{'lang'}{$lang} = 1;
        debug("File %s will be %s", $file, $lang);

    },
    $buildroot || '/'
);

open(my $hlang, '>', "$pkgname.lang") or die "canno't open $pkgname.lang\n";

foreach my $f (sort keys %finallist) {
    my ($lang, @otherlang) = keys %{ $finallist{$f}{'lang'} || {}};
    my $l = sprintf("%s%s%s",
        $finallist{$f}{'dir'} ? '%dir ' : '',
        @otherlang == 0 && $lang && !$finallist{$f}{'dir'} && $lang ne 'C'
            ? "%lang($lang) "
            : '', # skip if multiple lang, 'C' or dir
        $f
    );
    debug('OUT: %s', $l);
    print $hlang "$l\n";

}

close($hlang);

exit(0);

sub parent_to_own {
    my ($parent, $file, $lang) = @_;
    my @subdir = grep { $_ } split('/', substr($file, length($parent)));
    pop(@subdir);
    while (my $part = shift(@subdir)) {
        $parent .= "/$part";
        $finallist{$parent}{dir} = 1;
        $finallist{$file}{'lang'}{$lang} = 1;
        debug("Parent %s will be %s", $parent, $lang);
    }
}