aboutsummaryrefslogtreecommitdiffstats
path: root/mgaadv
blob: 78b1cf3f9ecdba3ca6f9028da3c922c84ecf3345 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
#!/usr/bin/perl -w

use strict;
use MGA::Advisories;
use Template;
use YAML qw(LoadFile DumpFile);
use File::Basename;

my %actions = (
    initqaconf => {
        run   => \&initqaconf,
        descr => 'Initialize configuration for QA team members',
        usage => <<END,
$0 initqaconf

Initialize a default configuration for QA team members, and open an
editor on the file.
END
    },
    list   => {
        run   => \&listadv,
        descr => 'List advisories',
        usage => <<END,
$0 list [filter...]

Print the list of published advisories. Optionally you can filter the
list with one or more filters. Possible filters are :
- advisory type
- distribution release
- package name
- CVE
- media

Examples :
 
 list advisories for package wireshark :
 \$ mgaadv list wireshark

 list security advisories for package wireshark :
 \$ mgaadv list security wireshark

 list advisories for CVE CVE-2013-3560
 \$ mgaadv list CVE-2013-3560

 list advisories for Mageia 2 in media tainted :
 \$ mgaadv list 2 tainted

END
    },
    mksite => {
        run   => \&mksite,
        descr => 'Generates the advisories web site',
        usage => <<END,
$0 mksite

Generates the advisories web site
END
    },
    process => {
        run   => \&process,
        descr => 'Process advisories',
        usage => <<END,
$0 process

Process advisories i.e. move the [S]RPMs, update website, send emails
END
    },
    new    => {
        run   => \&newadv,
        descr => 'Create a new advisory file',
        usage => <<END,
$0 new [type] [bugnum] [name]

Create a new advisory file. [type] should be security or bugfix,
[bugnum] is the bugzilla bug number and [name] is the package name.
END
    },
    nextid  => {
        run   => \&nextid,
        descr => 'Print next available ID',
        usage => <<END,
$0 nextid [type]

Print the next unused advisory ID for [type].
END
    },
    publish => {
        run => \&publish,
        descr => 'Assign an ID to an advisory file',
        usage => <<END
$0 publish [bugnum]

Assign a new ID to an advisory file.
END
    },
    'publish-all' => {
        run => \&publishall,
        descr => 'Publish all pending advisories',
        usage => <<END
$0 publish-all

Assign a new ID to all pending, validated advisories (subject to cross checks).
END
    },
    show   => {
        run   => \&showadv,
        descr => 'Show an advisory',
        usage => <<END,
$0 show [ID]

Show an advisory.
END
    },
    showjson   => {
        run   => \&showadvjson,
        descr => 'Show an advisory in JSON format',
        usage => <<END,
$0 showjson [ID]

Show an advisory in JSON format.
END
    },
    update => {
        run   => \&updateadv,
        descr => 'Update the advisories database',
        usage => <<END,
$0 update

Update the advisories database.
END
    },
    usage  => {
        run   => \&usage,
        descr => 'Show usage informations for an action',
        usage => <<END,
$0 usage [action]

Show action usage
END
    },
);

sub usage {
    if ($_[1] && $actions{$_[1]}) {
        print STDERR $actions{$_[1]}->{usage};
    } else {
        print STDERR "$0 [action] [options]\n";
        print STDERR "$0 usage [action]\n\n";
        print STDERR "Available actions:\n";
        print STDERR map { " - $_ : $actions{$_}->{descr}\n" } keys %actions;
    }
}
sub usageexit {
    usage(@_);
    exit 1;
}

sub mksite {
    my %advdb;
    $advdb{advisories} = MGA::Advisories::get_advisories();
    MGA::Advisories::publish_advisories(\%advdb);
    MGA::Advisories::sort_advisories(\%advdb);
    MGA::Advisories::output_pages(\%advdb);
    MGA::Advisories::dumpdb(\%advdb);
    MGA::Advisories::send_adv_mail(\%advdb);
    MGA::Advisories::send_report(\%advdb);
}

sub process {
    my %advdb;
    $advdb{advisories} = MGA::Advisories::get_advisories();
    MGA::Advisories::move_packages(\%advdb);
    MGA::Advisories::publish_advisories(\%advdb);
    MGA::Advisories::sort_advisories(\%advdb);
    MGA::Advisories::output_pages(\%advdb);
    MGA::Advisories::dumpdb(\%advdb);
    MGA::Advisories::send_adv_mail(\%advdb);
    MGA::Advisories::close_bugs(\%advdb);
    MGA::Advisories::send_report(\%advdb);
}

sub editor { $ENV{EDITOR} || $ENV{VISUAL} || '/usr/bin/editor' }

sub newadv {
    usageexit('usage', $_[0]) unless @_ == 4;
    my ($new, $type, $bugnum, $name) = @_;
    my $file = MGA::Advisories::newadv($type, $bugnum, $name);
    if ($file) {
        system(editor, $file);
    }
}

sub nextid {
    usageexit('usage', $_[0]) unless @_ == 2;
    my $type = $_[1];
    if (!$MGA::Advisories::config->{advisory_types}{$type}) {
        print STDERR "Unknown type $type\n";
        exit 1;
    }
    print MGA::Advisories::next_id(
        $MGA::Advisories::config->{advisory_types}{$type}{prefix},
        keys %{MGA::Advisories::get_advisories()}), "\n";
}

sub publish {
    usageexit('usage', $_[0]) unless @_ == 2;
    MGA::Advisories::assign_id($_[1]);
}

sub publishall {
    usageexit('usage', $_[0]) unless @_ == 1;
    MGA::Advisories::assign_ids();
}

sub listadv {
    shift;
    my %advdb;
    $advdb{advisories} = MGA::Advisories::get_advisories();
    MGA::Advisories::sort_advisories(\%advdb) if @_;
    MGA::Advisories::listadv(\%advdb, @_);
}

sub showadv {
    usageexit('usage', $_[0]) unless @_ == 2;
    my $adv = $_[1];
    my %advdb;
    $advdb{advisories} = MGA::Advisories::get_advisories();
    MGA::Advisories::showadv(\%advdb, $adv);
}

sub showadvjson {
    usageexit('usage', $_[0]) unless @_ == 2;
    my $adv = $_[1];
    my %advdb;
    $advdb{advisories} = MGA::Advisories::get_advisories();
    MGA::Advisories::showadvjson(\%advdb, $adv);
}

sub updateadv {
    usageexit('usage', $_[0]) unless @_ == 1;
    MGA::Advisories::download_advisories;
}

sub initqaconf {
    my $c = $MGA::Advisories::home_config_file;
    if (-f $c) {
        print STDERR "File $c already exists\n";
        exit 1;
    }
    my %defaultconf = (
        mode           => 'qa',
        out_dir        => $ENV{HOME} . '/mageia-advisories/html',
        status_dir     => $ENV{HOME} . '/mageia-advisories/status',
        advisories_dir => $ENV{HOME} . '/mageia-advisories/advisories',
    );
    DumpFile($c, \%defaultconf);
    system(editor, $c);
    my $newconf = LoadFile($c);
    foreach my $n ('out_dir', 'status_dir', 'advisories_dir') {
        mkdir dirname($newconf->{$n}) unless -d dirname($newconf->{$n});
    }
    foreach my $n ('out_dir', 'status_dir') {
        mkdir $newconf->{$n} unless -d $newconf->{$n};
    }
    if (! -d $newconf->{advisories_dir}) {
        system('svn', 'co', $MGA::Advisories::config->{advisories_repo_url},
            $newconf->{advisories_dir});
    }
}

if (@ARGV == 0 || !$actions{$ARGV[0]}) {
    usageexit();
}
$actions{$ARGV[0]}->{run}->(@ARGV);