#!/usr/bin/perl

use lib qw(/usr/lib/libDrakX);


use interactive;
use keyboard;
use Xconfigurator_consts;
use common qw(:system);
use c;

local $_ = join '', @ARGV;

/-h/ and die _("usage: keyboarddrake [--expert]\n");

$::expert = /-expert/;
$::isStandalone = 1;

my $in = interactive->vnew('su');

my $keyboard = $in->ask_from_listf_(_("Keyboard"),
				   _("Please, choose your keyboard layout."),
				   \&keyboard::keyboard2text,
				   [ keyboard::xmodmaps() ],
				   keyboard::read());

my $isNotDelete = $::expert && !$in->ask_yesorno("BackSpace", _("Do you want the BackSpace to return Delete in console?"), 1);

my $kmap = keyboard::keyboard2kmap($keyboard);
`loadkeys $kmap`;

my $xkb = keyboard::keyboard2xkb($keyboard);
`setxkbmap $xkb`;

my $f = "/etc/X11/XF86Config";
my $g = "/etc/X11/XF86Config-4";

substInFile {
    if (/^Section\s+"Keyboard"/ .. /^EndSection/) {
	s|^(\s*XkbLayout\s+).*|$1"$xkb"| 
	  and $_ .= join '', map { "    $_\n" } @{$xkb_options{$xkb} || []};
	s,^(\s*(XkbVariant|XkbOptions)\s+).*,,; # remove existing one
    }
} $f if -e $f && !$::testing;

substInFile {
    if (/Identifier\s+"Keyboard1"/ .. /^EndSection/) {
	s|^(\s*Option\s+"XkbLayout"\s+).*|$1"$xkb"| 
	  and $_ .= join '', map { /(\S+)(.*)/; qq(    Option "$1" $2\n) } @{$xkb_options{$xkb} || []};
	s,^(\s*Option\s+"(XkbVariant|XkbOptions)"\s+).*,,; # remove existing one
    }
} $g if -e $g && !$::testing;

keyboard::write('', $keyboard, $isNotDelete);

$in->exit(0);